iniciar-programa
define-nueva-instruccion g(n) como
repetir n veces gira-izquierda;
define-nueva-instruccion llena como
inicio
        mientras frente-libre hacer
        inicio
            avanza;
            si junto-a-zumbador entonces deja-zumbador;
        fin;
        mientras no-orientado-al-este hacer gira-izquierda;
        si frente-libre entonces
        inicio
            avanza;
            si izquierda-bloqueada entonces
            g(3)
            sino
            gira-izquierda;
            llena;
        fin
        sino
        inicio
            g(2);
            mientras frente-libre hacer avanza;
            gira-izquierda;
            mientras frente-libre hacer
            avanza;
            g(2);
        fin;
fin;
define-nueva-instruccion dfs como
inicio
    deja-zumbador;
    repetir 4 veces
    inicio
        si frente-libre entonces
        inicio
            avanza;
            si no-junto-a-zumbador entonces
            dfs;
            g(2);
            avanza;
            g(2);
        fin;
        gira-izquierda;
    fin;
fin;
define-nueva-instruccion suma(n) como
inicio
    si junto-a-zumbador entonces
    inicio
        coge-zumbador;
        suma(sucede(n))
    fin
    sino
    inicio
        avanza;
        repetir n veces deja-zumbador;
    fin;
fin;
define-nueva-instruccion dfsc como
inicio
    repetir 4 veces
    inicio
        si frente-libre entonces
        inicio
            avanza;
                si junto-a-zumbador entonces
                inicio
                    coge-zumbador;
                    si junto-a-zumbador entonces
                    deja-zumbador;
                    si no-junto-a-zumbador entonces
                    inicio
                        deja-zumbador;
                        g(2);
                        avanza;
                        g(2);
                        suma(0);
                        dfsc;
                        g(2);
                        suma(0);
                        g(2);
                    fin
                    sino
                    inicio
                        g(2);
                        avanza;
                        g(2);
                    fin;
                fin
                sino
                inicio
                    g(2);
                    avanza;
                    g(2);
                fin;
        fin;
        gira-izquierda;
    fin;
fin;
define-nueva-instruccion lleva(n) como
inicio
    si junto-a-zumbador entonces
    inicio
        coge-zumbador;
        lleva(sucede(n))
    fin
    sino
    inicio
        mientras no-orientado-al-oeste hacer gira-izquierda;
        dfs;
        mientras frente-libre hacer avanza;
        gira-izquierda;
        deja-zumbador;
        mientras frente-libre hacer avanza;
        repetir n veces
        si junto-a-zumbador entonces coge-zumbador;
        repetir n veces deja-zumbador;
        g(2);
        avanza;
        mientras no-junto-a-zumbador hacer avanza;
        g(3);
        coge-zumbador;
        avanza;
    fin;
fin;
define-nueva-instruccion checa como
inicio
    mientras junto-a-zumbador y frente-libre hacer
    avanza;
    si junto-a-zumbador entonces
    inicio
        mientras no-orientado-al-norte hacer gira-izquierda;
        si frente-libre entonces avanza
        sino
        apagate;
        si izquierda-bloqueada entonces g(3)
        sino
        gira-izquierda;
        checa;
    fin
    sino
    inicio
        mientras frente-libre y no-junto-a-zumbador hacer
        avanza;
        si junto-a-zumbador entonces
        inicio
            g(2);
            avanza;
            dfs;
            dfsc;
            lleva(0);
            checa;
        fin
        sino
        inicio
            mientras no-orientado-al-norte hacer gira-izquierda;
            si frente-libre entonces
            avanza
            sino
            apagate;
            si izquierda-bloqueada entonces
            g(3)
            sino
            gira-izquierda;
            mientras no-junto-a-zumbador y frente-libre hacer avanza;
            si no-junto-a-zumbador entonces apagate;
            checa;
        fin;
    fin;
fin;
    inicia-ejecucion
    llena;
    repetir 2 veces avanza;
    g(3);
    avanza;
    checa;
        apagate;
    termina-ejecucion
finalizar-programa
