iniciar-programa
    define-nueva-instruccion norte como mientras no orientado-al-norte hacer gira-izquierda;
    define-nueva-instruccion oeste como mientras no orientado-al-oeste hacer gira-izquierda;
    define-nueva-instruccion este como mientras no orientado-al-este hacer gira-izquierda;
    define-nueva-instruccion sur como mientras no orientado-al-sur hacer gira-izquierda;
    define-nueva-instruccion media-vuelta como repetir 2 veces gira-izquierda;

    define-nueva-instruccion ir11 como inicio
        oeste;
        mientras frente-libre hacer inicio
            avanza;
        fin;
        sur;
        mientras frente-libre hacer inicio
            avanza;
        fin;
        norte;
    fin;

    define-nueva-instruccion orientar como inicio
        avanza;
        este;
        avanza;
        nortE;
        mientras junto-a-zumbador y frente-libre hacer inicio
            avanza;
        fin;
        si no junto-a-zumbador entonces inicio
            sur;
            avanza;
        fin;
        este;
    fin;

    define-nueva-instruccion recoger como inicio
        si no junto-a-zumbador entonces inicio
            deja-zumbador;
            deja-zumbador;
            norte;
            si frente-libre entonces inicio
                avanza;
                recoger;
                sur;
                avanza;
            fin;
            este;
            si frente-libre entonces inicio
                avanza;
                recoger;
                oeste;
                avanza;
            fin;
            sur;
            si frente-libre entonces inicio
                avanza;
                recoger;
                norte;
                avanza;
            fin;
            oeste;
            si frente-libre entonces inicio
                avanza;
                recoger;
                este;
                avanza;
            fin;
        fin;
    fin;

    define-nueva-instruccion jalar como inicio
        si junto-a-zumbador entonces inicio
            coge-zumbador;
            jalar;
            deja-zumbador;
        fin sino inicio
            deja-zumbador;
            media-vuelta;
            avanza;
        fin;
    fin;

    define-nueva-instruccion pasar como inicio
        media-vuelta;
        si junto-a-zumbador entonces inicio
                coge-zumbador;
            si junto-a-zumbador entonces inicio
                deja-zumbador;
                jalar;
            fin sino inicio
                deja-zumbador;
                media-vuelta;
                avanza;
            fin;
        fin sino inicio
            media-vuelta;
            avanza;
        fin;
    fin;

    define-nueva-instruccion contar como inicio
        si junto-a-zumbador entonces inicio
            coge-zumbador;
            si junto-a-zumbador entonces inicio
                deja-zumbador;
                media-vuelta;
                avanza;
                jalar;
                norte;
                si frente-libre entonces inicio
                    avanza;
                    contar;
                    sur;
                    pasar;
                fin;
                este;
                si frente-libre entonces inicio
                    avanza;
                    contar;
                    oeste;
                    pasar;
                fin;
                sur;
                si frente-libre entonces inicio
                    avanza;
                    contar;
                    norte;
                    pasar;
                fin;
                oeste;
                si frente-libre entonces inicio
                    avanza;
                    contar;
                    este;
                    pasar;
                fin;
            fin sino inicio
                deja-zumbador;
            fin;
        fin;
    fin;

    define-nueva-instruccion camina como inicio
        mientras junto-a-zumbador hacer inicio
            avanza;
            si no junto-a-zumbador entonces inicio
                norte;
                avanza;
                si no junto-a-zumbador entonces inicio
                    oeste;
                    mientras frente-libre hacer inicio
                        avanza;
                    fin;
                    sur;
                    avanza;
                    avanza;
                    este;
                    avanza;
                fin sino inicio
                    sur;
                    avanza;
                    este;
                fin;
            fin;
        fin;
    fin;

    define-nueva-instruccion llevar11(n) como inicio
        si junto-a-zumbador entonces inicio
            repetir 3 veces inicio
                coge-zumbador;
            fin;
            llevar11(sucede(n));
        fin sino inicio
            deja-zumbador;
            ir11;
            repetir n veces inicio
                si junto-a-zumbador entonces inicio
                    coge-zumbador;
                fin;
            fin;
            repetir n veces inicio
                deja-zumbador;
            fin;
        fin;
    fin;

    define-nueva-instruccion monte-alban como inicio
        mientras junto-a-zumbador hacer inicio
            camina;
            si derecha-libre entonces inicio
                recoger;
                contar;
                llevar11(0);
                orientar;
            fin;
        fin;
    fin;

    inicia-ejecucion
        orientar;
        monte-alban;
        apagate;
    termina-ejecucion
finalizar-programa
