iniciar-programa
    define-nueva-instruccion gira(n) como repetir n veces gira-izquierda;

    define-nueva-instruccion uno_uno como inicio
        mientras no-orientado-al-sur hacer gira-izquierda;
        mientras frente-libre hacer avanza;
        gira(3);
        mientras frente-libre hacer avanza;
        gira(1);
    fin;

    define-nueva-instruccion comparar(x) como inicio
        si no(si-es-cero(x)) entonces inicio
            si junto-a-zumbador entonces inicio
                coge-zumbador;
                comparar(precede(x));
                deja-zumbador;
            fin sino inicio
                repetir x veces deja-zumbador;
            fin;
        fin;
    fin;

    define-nueva-instruccion mover como inicio
        si junto-a-zumbador entonces inicio
            coge-zumbador;
            mover;
            deja-zumbador;
        fin sino inicio
            deja-zumbador;
            avanza;
        fin;
    fin;

    define-nueva-instruccion verificar como inicio
        coge-zumbador;
        si junto-a-zumbador entonces inicio
            mover;
        fin sino inicio
            deja-zumbador;
            avanza;
        fin;
    fin;

    define-nueva-instruccion busqueda como inicio
        si no-junto-a-zumbador entonces inicio
            repetir 2 veces deja-zumbador;
            si frente-libre entonces inicio
                avanza;
                busqueda;
                gira(2);
                verificar;
                gira(2);
            fin;

            si derecha-libre entonces inicio
                gira(3);
                avanza;
                busqueda;
                gira(2);
                verificar;
                gira(3);
            fin;

            si izquierda-libre entonces inicio
                gira(1);
                avanza;
                busqueda;
                gira(2);
                verificar;
                gira(1);
            fin;
        fin;
    fin;

    define-nueva-instruccion cuenta(tam) como inicio
        si junto-a-zumbador entonces inicio
            coge-zumbador;
            cuenta(sucede(tam));
        fin sino inicio
            deja-zumbador;
            uno_uno;
            comparar(tam);
        fin;
    fin;

    define-nueva-instruccion buscar_espacio como inicio
        mientras junto-a-zumbador y frente-libre hacer avanza;
        si no-junto-a-zumbador y frente-libre entonces inicio
            busqueda;
            coge-zumbador;
            cuenta(0);
        fin sino inicio
            gira(2);
            si frente-libre entonces avanza;
            mientras junto-a-zumbador y frente-libre hacer avanza;
            si derecha-libre entonces inicio
                gira(3);
                avanza;
                gira(3);
                mientras no-junto-a-zumbador y frente-libre hacer avanza;
            fin;
        fin;
    fin;

    inicia-ejecucion
        avanza;
        gira(3);
        avanza;
        gira(3);
        mientras junto-a-zumbador hacer inicio
            buscar_espacio;
        fin;
        uno_uno;
        gira(2);
        apagate;
    termina-ejecucion
finalizar-programa
