iniciar-programa

    define-nueva-instruccion norte como
    inicio
        mientras no-orientado-al-norte hacer
        inicio
            gira-izquierda;
        fin;
    fin;

    define-nueva-instruccion sur como
    inicio
        mientras no-orientado-al-sur hacer
        inicio
            gira-izquierda;
        fin;
    fin;

    define-nueva-instruccion este como
    inicio
        mientras no-orientado-al-este hacer
        inicio
            gira-izquierda;
        fin;
    fin;

    define-nueva-instruccion oeste como
    inicio
        mientras no-orientado-al-oeste hacer
        inicio
            gira-izquierda;
        fin;
    fin;

    define-nueva-instruccion gira-derecha como
    inicio
        repetir 3 veces
        inicio
            gira-izquierda;
        fin;
    fin;

    define-nueva-instruccion gira-doble como
    inicio
        repetir 2 veces
        inicio
            gira-izquierda;
        fin;
    fin;

    define-nueva-instruccion camina como
    inicio
        mientras frente-libre hacer
        inicio
            avanza;
        fin;
    fin;

    define-nueva-instruccion volver-a-k como
    inicio
        sur;
        camina;
        oeste;
        camina;
        este;
    fin;

    define-nueva-instruccion regresa como
    inicio
        oeste;
        camina;
        este;
        avanza;
    fin;

    define-nueva-instruccion ir como
    inicio
        si orientado-al-oeste entonces
        inicio
           este;
           si junto-a-zumbador entonces
           inicio
              coge-zumbador;
           fin
           sino
           inicio
               deja-zumbador;
           fin;
        fin
        sino
        inicio
            avanza;
            si junto-a-zumbador entonces
            inicio
               coge-zumbador;
            fin
            sino
            inicio
                deja-zumbador;
            fin;
        fin;
    fin;

    define-nueva-instruccion pasa como
    inicio
        norte;
        si frente-libre entonces
        inicio
           avanza;
           oeste;
           si no-junto-a-zumbador entonces
           inicio
               volver-a-k;
               norte;
           fin;
        fin
        sino
        inicio
            volver-a-k;
            norte;
        fin;
    fin;

    define-nueva-instruccion llena(x) como
    inicio
        si no-junto-a-zumbador entonces
        inicio
            volver-a-k;
            norte;
            avanza;
            este;
            avanza;
            oeste;
            mientras (no(no-junto-a-zumbador y orientado-al-norte)) hacer
            inicio
                repetir x veces
                inicio
                    ir;
                fin;
                regresa;
                pasa;
            fin;
        fin
        sino
        inicio
            volver-a-k;
            norte;
            avanza;
            este;
            avanza;
            oeste;
            mientras (no(no-junto-a-zumbador y orientado-al-norte)) hacer
            inicio
                repetir sucede(x) veces
                inicio
                    ir;
                fin;
                regresa;
                pasa;
            fin;
        fin;
    fin;

    define-nueva-instruccion llenar(x) como
    inicio
        si (junto-a-zumbador y frente-libre) entonces
        inicio
            avanza;
            llenar(sucede(x));
        fin
        sino
        inicio
            llena(x);
        fin;
    fin;

    define-nueva-instruccion principio como
    inicio
        norte;
        avanza;
        este;
        avanza;
    fin;

    define-nueva-instruccion acarrea como
    inicio
        si junto-a-zumbador entonces
        inicio
            coge-zumbador;
            acarrea;
            deja-zumbador;
        fin
        sino
        inicio
            avanza;
        fin;
    fin;

    define-nueva-instruccion busqueda como
    inicio
        si junto-a-zumbador entonces
        inicio
            norte;
            si frente-libre entonces
            inicio
                avanza;
                si junto-a-zumbador entonces
                inicio
                    gira-doble;
                    avanza;
                    gira-doble;
                    acarrea;
                    busqueda;
                fin;
                sur;
                acarrea;
            fin;
            sur;
            si frente-libre entonces
            inicio
                avanza;
                si junto-a-zumbador entonces
                inicio
                    gira-doble;
                    avanza;
                    gira-doble;
                    acarrea;
                    busqueda;
                fin;
                norte;
                acarrea;
            fin;
            este;
            si frente-libre entonces
            inicio
                avanza;
                si junto-a-zumbador entonces
                inicio
                    gira-doble;
                    avanza;
                    gira-doble;
                    acarrea;
                    busqueda;
                fin;
                oeste;
                acarrea;
            fin;
            oeste;
            si frente-libre entonces
            inicio
                avanza;
                si junto-a-zumbador entonces
                inicio
                    gira-doble;
                    avanza;
                    gira-doble;
                    acarrea;
                    busqueda;
                fin;
                este;
                acarrea;
            fin;
        fin;
    fin;

    define-nueva-instruccion regresa-2 como
    inicio
        oeste;
        camina;
    fin;

    define-nueva-instruccion pasa-2 como
    inicio
        norte;
        si frente-libre entonces
        inicio
            avanza;
            oeste;
        fin
        sino
        inicio
            este;
            camina;
        fin;
    fin;

    define-nueva-instruccion cuenta(x) como
    inicio
        si frente-libre entonces
        inicio
           avanza;
           cuenta(x);
           avanza;
        fin
        sino
        inicio
            oeste;
            camina;
            repetir x veces
            inicio
                si junto-a-zumbador entonces
                inicio
                    coge-zumbador;
                fin;
            fin;
            repetir x veces
            inicio
                deja-zumbador;
            fin;
            norte;
        fin;
    fin;

    define-nueva-instruccion lleva(x) como
    inicio
        si junto-a-zumbador entonces
        inicio
            coge-zumbador;
            lleva(sucede(x));
        fin
        sino
        inicio
            sur;
            cuenta(x);
            este;
        fin;
    fin;

    define-nueva-instruccion ir-2 como
    inicio
        mientras (no(frente-bloqueado y orientado-al-este)) hacer
        inicio
            si orientado-al-oeste entonces
            inicio
               este;
               si junto-a-zumbador entonces
               inicio
                   busqueda;
                   lleva(0);
               fin;
            fin
            sino
            inicio
                avanza;
                si junto-a-zumbador entonces
                inicio
                    busqueda;
                    lleva(0);
                fin;
            fin;
        fin;
    fin;

    define-nueva-instruccion busca como
    inicio
        mientras (no((orientado-al-este y frente-bloqueado) y izquierda-bloqueada)) hacer
        inicio
            ir-2;
            regresa-2;
            pasa-2;
        fin;
    fin;

    inicia-ejecucion
        principio;
        llenar(0);
        volver-a-k;
        oeste;
        busca;
        apagate;
    termina-ejecucion
finalizar-programa
