iniciar-programa
    define-nueva-instruccion gira (n) como inicio
        repetir n veces
            gira-izquierda;
    fin;
    define-nueva-instruccion norte como inicio
        mientras no-orientado-al-norte hacer
            gira (1);
    fin;
    define-nueva-instruccion este como inicio
         mientras no-orientado-al-este hacer
             gira (1);
     fin;
     define-nueva-instruccion sur como inicio
        mientras no-orientado-al-sur hacer
            gira (1);
    fin;
    define-nueva-instruccion oeste como inicio
        mientras no-orientado-al-oeste hacer
            gira (1);
    fin;
    define-nueva-instruccion cuenta (n) como inicio
        si junto-a-zumbador entonces inicio
            coge-zumbador;
            cuenta (sucede(n));
        fin
        sino inicio
            deja-zumbador;
            avanza;
            repetir n veces
                deja-zumbador;
        fin;
    fin;
    define-nueva-instruccion busca2 como inicio
        deja-zumbador;
        deja-zumbador;
        norte;
        si frente-libre entonces inicio
            avanza;
            si no-junto-a-zumbador entonces inicio
                busca2;
                sur;
                cuenta (0);
            fin
            sino inicio
                sur;
                avanza;
            fin;
        fin;
        este;
        si frente-libre entonces inicio
            avanza;
            si no-junto-a-zumbador entonces inicio
                busca2;
                oeste;
                cuenta (0);
            fin
            sino inicio
                oeste;
                avanza;
            fin;
        fin;
        sur;
        si frente-libre entonces inicio
            avanza;
            si no-junto-a-zumbador entonces inicio
                busca2;
                norte;
                cuenta (0);
            fin
            sino inicio
                norte;
                avanza;
            fin;
        fin;
        oeste;
        si frente-libre entonces inicio
            avanza;
            si no-junto-a-zumbador entonces inicio
                busca2;
                este;
                cuenta (0);
            fin
            sino inicio
                este;
                avanza;
            fin;
        fin;
    fin;
    define-nueva-instruccion orienta como inicio
        sur;
        mientras frente-libre hacer
            avanza;
        oeste;
        mientras frente-libre hacer
            avanza;
        norte;
    fin;
    define-nueva-instruccion divide como inicio
        si junto-a-zumbador entonces inicio
            repetir 2 veces
                coge-zumbador;
            divide;
            deja-zumbador;
        fin
        sino inicio
            deja-zumbador;
            orienta;
            este;
            avanza;
        fin;
    fin;
    define-nueva-instruccion recorido como inicio
        este;
        avanza;
        norte;
        avanza;
        mientras junto-a-zumbador hacer
            avanza;
        sur;
        avanza;
        este;
        mientras junto-a-zumbador hacer
            avanza;
        oeste;
        avanza;
    fin;
    define-nueva-instruccion compara (n) como inicio
        si junto-a-zumbador entonces inicio
            coge-zumbador;
            compara (sucede(n));
        fin
        sino inicio
            avanza;
            repetir n veces inicio
                si junto-a-zumbador entonces
                    coge-zumbador;
            fin;
            repetir n veces
                deja-zumbador;
        fin;
    fin;
    define-nueva-instruccion monte como inicio
        mientras frente-libre y junto-a-zumbador hacer
            avanza;
        si no-junto-a-zumbador y frente-libre entonces inicio
            busca2;
            divide;
            oeste;
            compara (0);
            recorido;
            monte;
        fin;
        si frente-bloqueado y izquierda-libre entonces inicio
            sur;
            avanza;
            este;
            mientras frente-libre hacer
                avanza;
            oeste;
            mientras frente-libre y no-junto-a-zumbador hacer
                avanza;
            monte;
        fin;
    fin;
    inicia-ejecucion
        recorido;
        monte;
        apagate;
    termina-ejecucion
finalizar-programa