iniciar-programa
   define-nueva-instruccion gira(n) como
   inicio
      repetir n veces
        gira-izquierda;
   fin;
   define-nueva-instruccion cuenta(n) como
   inicio
      si junto-a-zumbador entonces
      inicio
            coge-zumbador;
            cuenta(sucede(n));
            si orientado-al-este entonces
               deja-zumbador;
      fin
      sino
      inicio
         gira-izquierda;
         avanza;
         repetir n veces
            si junto-a-zumbador entonces
               coge-zumbador;
         si no-junto-a-zumbador entonces
         inicio
            repetir n veces
               deja-zumbador;
            gira-izquierda;
         fin;
      fin;
   fin;
   define-nueva-instruccion izq1 como
   inicio
       si frente-libre entonces
       inicio
          avanza;
          izq1;
          avanza;
       fin
       sino
       inicio
          si orientado-al-oeste entonces
          inicio
             gira-izquierda;
             izq1;
             gira(3);
          fin
          sino
          inicio
              cuenta(0);
              mientras no-orientado-al-oeste hacer
                 gira-izquierda;
             avanza;
             gira(3);
          fin;
       fin;
    fin;
   define-nueva-instruccion izq como
   inicio
       si frente-libre entonces
       inicio
          avanza;
          izq;
          avanza;
       fin
       sino
       inicio
          si orientado-al-oeste entonces
          inicio
             gira-izquierda;
             izq;
             gira(3);
          fin
          sino
          inicio
              deja-zumbador;
              gira(2);
          fin;
       fin;
    fin;

   define-nueva-instruccion lleva como
   inicio
       repetir 4 veces
       inicio
          si orientado-al-oeste entonces
          inicio
             izq;
             gira(2);
          fin;
          gira-izquierda;
       fin;
   fin;
   define-nueva-instruccion dfs como
   inicio
      deja-zumbador;
      deja-zumbador;
      lleva;
      repetir 4 veces
      inicio
          avanza;
          si no-junto-a-zumbador entonces
          inicio
             dfs;
          fin;
          gira(2);
          avanza;
          gira(2);
          gira-izquierda;
      fin;
   fin;
   define-nueva-instruccion trae como
   inicio
      si junto-a-zumbador entonces
      inicio
         coge-zumbador;
         trae;
         deja-zumbador;
      fin
      sino
         avanza;
    fin;
   define-nueva-instruccion per2 como
   inicio
         mientras junto-a-zumbador y frente-libre hacer
         inicio
            gira-izquierda;
            mientras junto-a-zumbador hacer
            inicio
               mientras frente-libre y junto-a-zumbador hacer
               inicio
                  avanza;
                  si no-junto-a-zumbador entonces
                  inicio
                     dfs;
                     gira-izquierda;
                     izq1;
                     gira-izquierda;
                  fin
                  sino
                  inicio
                     coge-zumbador;
                     si no-junto-a-zumbador entonces
                        deja-zumbador
                     sino
                     inicio
                        coge-zumbador;
                        si no-junto-a-zumbador entonces
                        inicio
                           repetir 2 veces
                              deja-zumbador;
                        fin
                        sino
                           coge-zumbador;
                      fin;
                  fin;
                fin;
                repetir 3 veces
                   deja-zumbador;
                gira(2);
                mientras frente-libre hacer
                   avanza;
                gira(2);
                avanza;
                gira(3);
                si frente-libre entonces
                inicio
                avanza;
                gira-izquierda;
                fin
                sino
                inicio
                    gira(2);
                    mientras frente-libre hacer
                       avanza;
                    gira-izquierda;
                    avanza;
                    gira-izquierda;
                    avanza;
                    gira(2);
                    trae;
                   apagate;
                fin;
         fin;
       fin;
   fin;
   define-nueva-instruccion per1 como
   inicio
      repetir 4 veces
      inicio
         mientras junto-a-zumbador y frente-libre hacer
         inicio
            deja-zumbador;
            deja-zumbador;
            avanza;
         fin;
         si junto-a-zumbador entonces
         inicio
            deja-zumbador;
            deja-zumbador;
            gira-izquierda;
         fin
         sino
         inicio
            gira(2);
            avanza;
            gira(3);
          fin;
          avanza;
       fin;
   fin;

    inicia-ejecucion
       avanza;
       gira(3);
       avanza;
       avanza;
       per1;
       per2;
       mientras no-orientado-al-oeste hacer
         gira-izquierda;
       mientras frente-libre hacer
          avanza;
       gira-izquierda;
       mientras frente-libre hacer
          avanza;
       gira-izquierda;
          avanza;
       gira(2);
       trae;
        apagate;
    termina-ejecucion
finalizar-programa
