iniciar-programa
define-nueva-instruccion este como mientras no-orientado-al-este hacer gira-izquierda;
define-nueva-instruccion oeste como mientras no-orientado-al-oeste hacer gira-izquierda;

define-nueva-instruccion resultado(n) como
    inicio
    si frente-libre entonces
        inicio
            avanza;
            resultado(sucede(n));
        fin
    sino
        inicio
        mientras junto-a-zumbador hacer coge-zumbador;
            repetir n veces deja-zumbador;
            apagate;
        fin;
    fin;

define-nueva-instruccion simulaMex(n) como
    inicio
    si junto-a-zumbador entonces
        inicio
            coge-zumbador;
            simulaMex(sucede(n));
        fin
    sino
        inicio
            este;
        repetir n veces
            inicio
            si junto-a-zumbador entonces
                inicio
                    oeste;
                    resultado(1);
                fin;
                avanza;
            fin;
            si junto-a-zumbador entonces
                inicio
                    oeste;
                    resultado(1);
                fin;
            repetir n veces deja-zumbador;
            si frente-libre entonces avanza;
        fin;
    fin;

define-nueva-instruccion simulaEstado(n) como
    inicio
    si junto-a-zumbador entonces
        inicio
            coge-zumbador;
            simulaEstado(sucede(n));
        fin
    sino
        inicio
            oeste;
        repetir n veces
            inicio
            si junto-a-zumbador entonces resultado(1);
                avanza;
            fin;
            si junto-a-zumbador entonces resultado(1);
            repetir n veces deja-zumbador;
        si frente-libre entonces avanza;
        fin;
    fin;

define-nueva-instruccion realiza como
    inicio
        este;
        si frente-libre entonces avanza sino
        inicio
        mientras junto-a-zumbador hacer coge-zumbador;
            deja-zumbador;
            apagate;
        fin;
    mientras no-orientado-al-sur hacer
        inicio
            mientras no-junto-a-zumbador hacer avanza;
            simulaEstado(0);
            mientras no-junto-a-zumbador hacer avanza;
            simulaMex(0);
        fin;
    fin;

    inicia-ejecucion
        realiza;
        apagate;
    termina-ejecucion
finalizar-programa
