iniciar-programa

    define-nueva-instruccion norte como mientras no orientado-al-norte hacer gira-izquierda;
    define-nueva-instruccion sur como mientras no orientado-al-sur hacer gira-izquierda;
    define-nueva-instruccion este como mientras no orientado-al-este hacer gira-izquierda;
    define-nueva-instruccion oeste como mientras no orientado-al-oeste hacer gira-izquierda;

    define-nueva-instruccion final(n) como inicio
        si frente-libre entonces inicio
            avanza;
            final(sucede(n));
        fin sino inicio
            mientras junto-a-zumbador hacer coge-zumbador;
            repetir sucede(n) veces deja-zumbador;
            apagate;
        fin;
    fin;

    define-nueva-instruccion dos(n) como inicio
        si junto-a-zumbador entonces inicio
            coge-zumbador;
            dos(sucede(n));
        fin sino inicio
            repetir precede(n) veces inicio
                si frente-libre y no orientado-al-este entonces inicio
                    avanza;
                fin;
            fin;
            avanza;
            si junto-a-zumbador entonces inicio
                final(0);
            fin;
            repetir n veces deja-zumbador;
            oeste;
            mientras frente-libre hacer avanza;
            este;
            mientras no junto-a-zumbador hacer avanza;
            mientras junto-a-zumbador hacer coge-zumbador;
            avanza;
        fin;
    fin;

    define-nueva-instruccion marca(n) como inicio
        repetir precede(n) veces inicio
            si frente-libre y no orientado-al-oeste entonces inicio
                avanza;
            fin;
        fin;
        repetir n veces deja-zumbador;
        avanza;
        si junto-a-zumbador entonces inicio
            oeste;
            avanza;
            final(0);
        fin;
        mientras frente-libre hacer avanza;
        oeste;
        mientras no junto-a-zumbador y frente-libre hacer avanza;
        dos(0);
    fin;

    define-nueva-instruccion uno(n) como inicio
        si junto-a-zumbador entonces inicio
            coge-zumbador;
            uno(sucede(n));
        fin sino inicio
            mientras no junto-a-zumbador hacer inicio
                marca(n);
            fin;
        fin;
    fin;

    inicia-ejecucion
        este;
        uno(0);
        apagate;
    termina-ejecucion
finalizar-programa
