iniciar-programa
    define-nueva-instruccion norte como mientras no-orientado-al-norte hacer gira-izquierda;
    define-nueva-instruccion este como mientras no-orientado-al-este hacer gira-izquierda;
    define-nueva-instruccion oeste como mientras no-orientado-al-oeste hacer gira-izquierda;
    define-nueva-instruccion sur como mientras no-orientado-al-sur hacer gira-izquierda;
    define-nueva-instruccion corre como mientras frente-libre hacer avanza;
    define-nueva-instruccion mueve-pasos como inicio
        si junto-a-zumbador entonces inicio
            coge-zumbador;
            mueve-pasos;
            deja-zumbador;
        fin sino inicio
            norte;
            avanza;
        fin;
    fin;
    define-nueva-instruccion limpia como inicio
        mueve-pasos;
        sur;
        avanza;
        este;
        corre;
        mueve-pasos;
        sur;
        avanza;
        oeste;
        corre;
    fin;
    define-nueva-instruccion paso1(x) como inicio
        repetir x veces inicio
            si frente-libre entonces inicio
                si no-orientado-al-norte entonces avanza;
            fin sino inicio
                gira-izquierda;
            fin;
        fin;
    fin;
    define-nueva-instruccion recoge(x) como inicio
        si junto-a-zumbador entonces inicio
             coge-zumbador;
             recoge(sucede(x));
         fin sino inicio
             repetir x veces deja-zumbador;
             repetir 2 veces gira-izquierda;
             avanza;
             mientras no-junto-a-zumbador hacer avanza;
         fin;
         deja-zumbador;
     fin;
    define-nueva-instruccion pasosDF(x) como inicio
        si junto-a-zumbador entonces inicio
            coge-zumbador;
            pasosDF(sucede(x));
        fin sino inicio
            sur;
            avanza;
            este;
            paso1(precede(x));
            deja-zumbador;
            mientras no-orientado-al-norte hacer inicio
                paso1(x);
                si no-orientado-al-norte entonces inicio
                    deja-zumbador;
                    repetir 2 veces gira-izquierda;
                    avanza;
                    mientras no-junto-a-zumbador hacer avanza;
                    recoge(0);
                    coge-zumbador;
                fin;
            fin;
        fin;
    fin;
    define-nueva-instruccion comprueba(x) como inicio
        repetir x veces inicio
            si junto-a-zumbador entonces inicio
                coge-zumbador;
            fin sino inicio
                norte;
            fin;
        fin;
    fin;
    define-nueva-instruccion cuentaFinal como inicio
        si frente-libre entonces inicio
            avanza;
            cuentaFinal;
        fin sino inicio
            mientras junto-a-zumbador hacer coge-zumbador;
        fin;
        deja-zumbador;
    fin;
    define-nueva-instruccion compara(x) como inicio
        si junto-a-zumbador entonces inicio
            coge-zumbador;
            compara(sucede(x));
        fin sino inicio
            repetir x veces deja-zumbador;
            sur;
            avanza;
            comprueba(x);
            si orientado-al-norte entonces inicio
                avanza;
            fin sino inicio
                si junto-a-zumbador entonces inicio
                    norte;
                    avanza;
                fin sino inicio
                    oeste;
                    cuentaFinal;
                    apagate;
                fin;
            fin;
        fin;
    fin;
    define-nueva-instruccion pasosOax(x) como inicio
        si junto-a-zumbador entonces inicio
            coge-zumbador;
            pasosOax(sucede(x));
        fin sino inicio
            oeste;
            paso1(x);
            deja-zumbador;
            mientras no-orientado-al-sur hacer inicio
                compara(0);
                oeste;
                si no-orientado-al-sur entonces inicio
                    paso1(x);
                    deja-zumbador;
                    repetir 2 veces gira-izquierda;
                    avanza;
                    mientras no-junto-a-zumbador hacer avanza;
                    recoge(0);
                    coge-zumbador;
                fin;
            fin;
        fin;
    fin;
    inicia-ejecucion
        limpia;
        norte;
        avanza;
        sur;
        pasosDF(0);
        avanza;
        pasosOax(0);
        apagate;
    termina-ejecucion
finalizar-programa
