iniciar-programa

define-nueva-instruccion gira(n) como repetir n veces gira-izquierda;

define-nueva-instruccion sumar(a) como inicio
    si junto-a-zumbador entonces inicio
        coge-zumbador;
        sumar(sucede(a));
    fin sino inicio
        repetir a veces deja-zumbador;
        avanza;
        mientras no-junto-a-zumbador hacer avanza;
        repetir a veces deja-zumbador;
        gira(2);
    fin;
fin;

define-nueva-instruccion medir(b) como inicio
    si junto-a-zumbador entonces inicio
        coge-zumbador;
        medir(sucede(b));
    fin sino inicio
        mientras frente-libre o no-junto-a-zumbador hacer inicio
            repetir b veces inicio
                si orientado-al-este entonces inicio
                    avanza;
                fin sino inicio
                    mientras frente-libre hacer avanza;
                    gira(1);
                    avanza;
                    gira(1);
                fin;
            fin;
            deja-zumbador;
        fin;
        gira(2);
    fin;
fin;

define-nueva-instruccion contar(c) como inicio
    si frente-libre entonces inicio
        avanza;
        si junto-a-zumbador entonces inicio
            coge-zumbador;
            contar(sucede(c));
        fin sino inicio
            contar(c);
        fin;
    fin sino inicio
        repetir sucede(c) veces deja-zumbador;
    fin;
fin;

define-nueva-instruccion multiplicar(d) como inicio
    si junto-a-zumbador entonces inicio
        coge-zumbador;
        multiplicar(sucede(d));
    fin sino inicio
        repetir d veces deja-zumbador;
        avanza;
        repetir d veces deja-zumbador;
        gira(2);
        avanza;
        gira(2);
    fin;
fin;

define-nueva-instruccion producto(e) como inicio
    si junto-a-zumbador entonces inicio
        coge-zumbador;
        producto(sucede(e));
    fin sino inicio
        avanza;
        gira(2);
        repetir e veces inicio
            multiplicar(0);
        fin;
    fin;
fin;

define-nueva-instruccion subir(x) como inicio
    si junto-a-zumbador entonces inicio
        coge-zumbador;
        subir(sucede(x));
    fin sino inicio
        avanza;
        gira(1);
        repetir x veces deja-zumbador;
    fin;
fin;

    inicia-ejecucion
    subir(0);
    gira(1);
    avanza;
    gira(1);
    mientras no-junto-a-zumbador hacer avanza;
    gira(1);
    subir(0);
    mientras frente-libre hacer avanza;
    gira(2);

    sumar(0);
    medir(0);
    coge-zumbador;
    contar(0);
    gira(3);
    producto(0);

        apagate;
    termina-ejecucion
finalizar-programa
