iniciar-programa
    define-nueva-instruccion media-vuelta como
        repetir 2 veces
            gira-izquierda;
    define-nueva-instruccion gira-derecha como
        repetir 3 veces
            gira-izquierda;
    define-nueva-instruccion pasos(x) como
        si junto-a-zumbador entonces inicio
            coge-zumbador;
            pasos(sucede(x));
            deja-zumbador;
        fin
        sino inicio
            repetir x veces
                si frente-libre entonces
                    avanza;
            si junto-a-zumbador entonces
                mientras no-orientado-al-sur hacer
                    gira-izquierda;
        fin;
    define-nueva-instruccion vuelta como inicio
        pasos(0);
        si frente-libre entonces
            avanza;
        si no-orientado-al-sur entonces inicio
            mientras frente-libre y no-junto-a-zumbador hacer
                avanza;
            media-vuelta;
            pasos(0);
            si no-orientado-al-sur entonces inicio
                mientras frente-libre hacer
                    avanza;
                media-vuelta;
                mientras no-junto-a-zumbador hacer
                    avanza;
            fin;
        fin;
    fin;
    define-nueva-instruccion cuenta como
        si frente-libre entonces inicio
            avanza;
            cuenta;
            deja-zumbador;
        fin;
    inicia-ejecucion
        gira-derecha;
        si junto-a-zumbador entonces inicio
            coge-zumbador;
            pasos(0);    
            deja-zumbador;
            si frente-libre entonces
                avanza;
        fin;
        mientras frente-libre y no-junto-a-zumbador hacer
            avanza;
        media-vuelta;
        mientras no orientado-al-sur hacer inicio
            vuelta;
        fin;
        mientras no-orientado-al-oeste hacer
            gira-izquierda;
        cuenta;
        deja-zumbador;
        apagate;
    termina-ejecucion
finalizar-programa
