iniciar-programa
    define-nueva-instruccion este como inicio
        mientras no-orientado-al-este hacer
            gira-izquierda;
    fin;
    define-nueva-instruccion oeste como inicio
        mientras no-orientado-al-oeste hacer
            gira-izquierda;
    fin;
    define-nueva-instruccion sur como inicio
        mientras no-orientado-al-sur hacer
            gira-izquierda;
    fin;
    define-nueva-instruccion norte como inicio
        mientras no-orientado-al-norte hacer
            gira-izquierda;
    fin;
    define-nueva-instruccion deja (n) como inicio
        repetir n veces deja-zumbador;
    fin;
    define-nueva-instruccion ubica1 como inicio
        oeste;
        mientras frente-libre hacer
            avanza;
        sur;
        mientras frente-libre hacer
            avanza;
        este;
    fin;
    define-nueva-instruccion ubicaO como inicio
        mientras orientado-al-este hacer inicio
            si junto-a-zumbador entonces inicio
                si frente-libre entonces inicio
                    avanza;
                fin
                sino inicio
                    oeste;
                fin;
            fin
            sino inicio
                oeste;
                si frente-libre entonces
                    avanza;
            fin;
        fin;
    fin;
    define-nueva-instruccion UbicaInicio como inicio
        ubica1;
        ubicaO;
    fin;
    define-nueva-instruccion compara (n) como inicio
        repetir n veces inicio
            si orientado-al-este entonces inicio
                si no-junto-a-zumbador entonces inicio
                    deja (n);
                    coge-zumbador;
                    norte;
                fin
                sino inicio
                    coge-zumbador;
                fin;
            fin
            sino inicio
                coge-zumbador;
            fin;
        fin;
    fin;
    define-nueva-instruccion marca como inicio
        norte;
        avanza;
        deja-zumbador;
        sur;
        avanza;
        este;
    fin;
    define-nueva-instruccion next como inicio
        si frente-libre entonces inicio
            avanza;
            si no-junto-a-zumbador entonces inicio
                oeste;
                avanza;
                norte;
            fin;
        fin
        sino inicio
            norte;
        fin;
    fin;
    define-nueva-instruccion dejar (n) como inicio
        este;
        compara (n);
        si orientado-al-este entonces inicio
            si junto-a-zumbador entonces inicio
                deja (n);
                coge-zumbador;
                si no-junto-a-zumbador entonces inicio
                    deja-zumbador;
                fin;
                deja-zumbador;
            fin
            sino inicio
                deja (sucede (n));
            fin;
        fin
        sino inicio
            mientras junto-a-zumbador hacer
                coge-zumbador;
            deja (n);
            si no-junto-a-zumbador entonces inicio
                deja-zumbador;
            fin;
            deja-zumbador;
        fin;
    fin;
    define-nueva-instruccion pon (n) como inicio
        si orientado-al-norte entonces inicio
            si junto-a-zumbador entonces inicio
                coge-zumbador;
                pon (sucede (n));
            fin
            sino inicio
                deja (n);
                oeste;
                pon (n);
                sur;
                avanza;
            fin;
        fin
        sino inicio
            si frente-libre entonces inicio
                avanza;
                si junto-a-zumbador entonces inicio
                    pon (n);
                    avanza;
                fin
                sino inicio
                    este;
                    avanza;
                    dejar (n);
                    este;
                fin;
            fin
            sino inicio
                dejar (n);
                este;
            fin;
        fin;
    fin;
    define-nueva-instruccion checar (n) como inicio
        si junto-a-zumbador entonces inicio
            coge-zumbador;
            checar (sucede (n));
        fin
        sino inicio
            deja (n);
            este;
            si frente-libre entonces inicio
                avanza;
                si junto-a-zumbador entonces inicio
                    mientras no-orientado-al-norte hacer inicio
                        compara (n);
                        si orientado-al-este entonces inicio (* N >= X *)
                            si junto-a-zumbador entonces inicio
                                deja (n);
                                norte;
                                avanza;
                                pon (0);
                            fin
                            sino inicio
                                deja (n);
                            fin;
                            este;
                            next;
                        fin
                        sino inicio (* N < X *)
                            este;
                            next;
                        fin;
                    fin;
                    avanza;
                    oeste;
                    mientras frente-libre hacer inicio
                        avanza;
                        si no-junto-a-zumbador entonces inicio
                            sur;
                            avanza;
                            este;
                            avanza;
                            sur;
                        fin;
                    fin;
                    si orientado-al-oeste entonces inicio
                        sur;
                        avanza;
                    fin;
                fin
                sino inicio
                    oeste;
                    avanza;
                fin;
            fin;
        fin;
    fin;
    define-nueva-instruccion mayor (n) como inicio
        si junto-a-zumbador entonces inicio
            coge-zumbador;
            mayor (sucede (n));
        fin
        sino inicio
            mientras frente-libre hacer inicio
                avanza;
                repetir n veces inicio
                    si junto-a-zumbador entonces
                        coge-zumbador;
                fin;
                si junto-a-zumbador entonces inicio
                    deja (n);
                    mayor (0);
                fin;
            fin;
            si frente-bloqueado entonces inicio
                sur;
                avanza;
                mientras junto-a-zumbador hacer
                    coge-zumbador;
                deja (n);
                apagate;
            fin;
        fin;
    fin;
    define-nueva-instruccion matriuskas como inicio
        mientras orientado-al-este hacer inicio
            marca;
            checar (0);
            oeste;
            si frente-libre entonces inicio
                avanza;
                este;
            fin;
        fin;
        UbicaInicio;
        norte;
        avanza;
        oeste;
        mayor (0);
    fin;
    inicia-ejecucion
        UbicaInicio;
        este;
        matriuskas;
        apagate;
    termina-ejecucion
finalizar-programa
