iniciar-programa

    define-nueva-instruccion norte como mientras no orientado-al-norte hacer gira-izquierda;
    define-nueva-instruccion sur como mientras no orientado-al-sur hacer gira-izquierda;
    define-nueva-instruccion este como mientras no orientado-al-este hacer gira-izquierda;
    define-nueva-instruccion oeste como mientras no orientado-al-oeste hacer gira-izquierda;
    define-nueva-instruccion media-vuelta como repetir 2 veces gira-izquierda;

    define-nueva-instruccion marcar como inicio
        norte;
        repetir 2 veces avanza;
        deja-zumbador;
        sur;
        repetir 2 veces avanza;
        este;
    fin;

    define-nueva-instruccion quita(n) como inicio
        si junto-a-zumbador entonces inicio
            coge-zumbador;
            quita(n);
            coge-zumbador;
        fin sino inicio
            repetir n veces deja-zumbador;
        fin;
    fin;

    define-nueva-instruccion orientar como inicio
        este;
        mientras frente-libre hacer avanza;
        oeste;
        mientras no junto-a-zumbador y frente-libre hacer avanza;
        si junto-a-zumbador entonces inicio
            norte;
            avanza;
            deja-zumbador;
            sur;
            avanza;
            oeste;
            si frente-libre entonces inicio
                avanza;
            fin;
            mientras no junto-a-zumbador y frente-libre hacer avanza;
            si frente-bloqueado y no junto-a-zumbador entonces inicio
                este;
                mientras no junto-a-zumbador y frente-libre hacer avanza;
                si junto-a-zumbador entonces inicio
                    norte;
                    avanza;
                    si junto-a-zumbador entonces inicio
                        sur;
                        avanza;
                        oeste;
                        mientras frente-libre hacer avanza;
                        mientras junto-a-zumbador hacer coge-zumbador;
                        deja-zumbador;
                        apagate;
                    fin;
                fin;

            fin;
            este;
        fin;
    fin;

    define-nueva-instruccion compara(n) como inicio
        repetir n veces inicio
            si junto-a-zumbador y no orientado-al-sur entonces inicio
                coge-zumbador;
                norte;
            fin sino inicio
                sur;
                deja-zumbador;
            fin;
        fin;
    fin;

    define-nueva-instruccion coge(n) como inicio
        si junto-a-zumbador entonces inicio
            coge-zumbador;
            coge(sucede(n));
        fin sino inicio
            repetir n veces deja-zumbador;
            mientras orientado-al-norte hacer inicio
                norte;
                avanza;
                oeste;
                mientras no junto-a-zumbador y frente-libre hacer avanza;
                coge-zumbador;
                sur;
                avanza;
                norte;
                si junto-a-zumbador entonces inicio
                    compara(n);
                    si orientado-al-norte entonces inicio
                        repetir n veces deja-zumbador;
                        coge(0);
                    fin sino inicio
                        si orientado-al-sur entonces inicio
                            quita(n);
                            norte;
                        fin;
                    fin;
                fin sino inicio
                    repetir sucede(n) veces deja-zumbador;
                    sur;
                    avanza;
                    oeste;
                    si frente-libre entonces inicio
                        avanza;
                        mientras no junto-a-zumbador y frente-libre hacer avanza;
                        media-vuelta;
                    fin;
                fin;
            fin;
        fin;
    fin;

    define-nueva-instruccion ubicate como inicio
        oeste;
        mientras no junto-a-zumbador y frente-libre hacer avanza;
        coge-zumbador;
        sur;
        avanza;
        norte;
        si junto-a-zumbador entonces inicio
            coge(0);
        fin sino inicio
            deja-zumbador;
            sur;
            avanza;
            oeste;
            si frente-libre entonces inicio
                avanza;
                mientras no junto-a-zumbador y frente-libre hacer avanza;
                media-vuelta;
            fin;
        fin;
    fin;

    define-nueva-instruccion matriuska(n) como inicio
        si junto-a-zumbador entonces inicio
            coge-zumbador;
            matriuska(sucede(n));
        fin sino inicio
            repetir n veces deja-zumbador;
            marcar;
            si frente-libre entonces inicio
                avanza;
                mientras no junto-a-zumbador y frente-libre hacer avanza;
                mientras junto-a-zumbador y no orientado-al-oeste hacer inicio
                    compara(n);
                    si orientado-al-norte y junto-a-zumbador entonces inicio
                        repetir n veces deja-zumbador;
                        norte;
                        marcar;
                        si frente-libre entonces inicio
                            avanza;
                            mientras no junto-a-zumbador y frente-libre hacer avanza;
                            si no junto-a-zumbador y frente-bloqueado entonces oeste;
                        fin sino inicio
                            oeste;
                        fin;
                    fin sino inicio
                        si orientado-al-sur entonces inicio
                            quita(n);
                            este;
                            si frente-libre entonces inicio
                                avanza;
                                mientras no junto-a-zumbador y frente-libre hacer avanza;
                                si no junto-a-zumbador y frente-bloqueado entonces oeste;
                            fin sino inicio
                                oeste;
                            fin;
                        fin sino inicio
                            si no junto-a-zumbador entonces inicio
                                repetir n veces deja-zumbador;
                                este;
                                si frente-libre entonces inicio
                                    avanza;
                                    mientras no junto-a-zumbador y frente-libre hacer avanza;
                                    si no junto-a-zumbador y frente-bloqueado entonces oeste;
                                fin sino inicio
                                    oeste;
                                fin;
                            fin;
                        fin;
                    fin;
                fin;
                oeste;
                mientras no junto-a-zumbador y frente-libre hacer avanza;
                norte;
                repetir 2 veces avanza;
                ubicate;
            fin;
        fin;
    fin;

    define-nueva-instruccion mayor(n) como inicio
        repetir n veces inicio
            si junto-a-zumbador entonces coge-zumbador;
        fin;
    fin;

    define-nueva-instruccion llevar(n) como inicio
        si junto-a-zumbador entonces inicio
            coge-zumbador;
            llevar(sucede(n));
        fin sino inicio
            si frente-libre entonces inicio
                avanza;
                mientras no junto-a-zumbador y frente-libre hacer avanza;
                si junto-a-zumbador entonces inicio
                    mayor(n);
                    si junto-a-zumbador entonces inicio
                        repetir n veces deja-zumbador;
                        llevar(0);
                    fin sino inicio
                        repetir n veces deja-zumbador;
                        llevar(0);
                    fin;
                fin sino inicio
                    si frente-bloqueado y no junto-a-zumbador entonces inicio
                        sur;
                        avanza;
                        repetir n veces deja-zumbador;
                        apagate;
                    fin
                fin;
            fin sino inicio
                sur;
                avanza;
                mientras junto-a-zumbador hacer coge-zumbador;
                repetir n veces deja-zumbador;
                apagate;
            fin;
        fin;
    fin;

    define-nueva-instruccion final como inicio
        sur;
        mientras frente-libre hacer avanza;
        este;
        mientras frente-libre hacer avanza;
        norte;
        avanza;
        oeste;
        mientras no junto-a-zumbador y frente-libre hacer avanza;
        mientras no orientado-al-este hacer inicio
            llevar(0);
        fin;
    fin;

    inicia-ejecucion
        sur;
        si frente-bloqueado y izquierda-bloqueada y derecha-bloqueada y junto-a-zumbador entonces inicio
            mientras junto-a-zumbador hacer coge-zumbador;
            deja-zumbador;
            apagate;
        fin sino inicio
            si frente-bloqueado y izquierda-bloqueada y derecha-bloqueada y  no-junto-a-zumbador entonces inicio
                apagate;
            fin;
        fin;
        orientar;
        mientras no orientado-al-oeste hacer inicio

                mientras no junto-a-zumbador y frente-libre hacer avanza;
                norte;
                avanza;
                si no junto-a-zumbador entonces inicio
                    sur;
                    avanza;
                    matriuska(0);
                fin sino inicio
                    oeste;
                fin;


        fin;
        final;
        apagate;
    termina-ejecucion
finalizar-programa
