iniciar-programa

    define-nueva-instruccion norte como mientras no-orientado-al-norte hacer gira-izquierda;
    define-nueva-instruccion este como mientras no-orientado-al-este hacer gira-izquierda;
    define-nueva-instruccion oeste como mientras no-orientado-al-oeste hacer gira-izquierda;
    define-nueva-instruccion sur como mientras no-orientado-al-sur hacer gira-izquierda;

    define-nueva-instruccion comienza como inicio
        este;
        mientras frente-libre hacer avanza;
        oeste;
        mientras no-junto-a-zumbador hacer avanza;
    fin;

    define-nueva-instruccion comparar(n) como inicio
        si junto-a-zumbador y no si-es-cero(n) entonces inicio
            coge-zumbador;
            comparar(precede(n));
            deja-zumbador;
        fin sino inicio
            repetir n veces deja-zumbador;
        fin;
    fin;

    define-nueva-instruccion cuenta(z) como inicio
        si junto-a-zumbador entonces inicio
            coge-zumbador;
            cuenta(sucede(z));
        fin sino inicio
            avanza;
            comparar(z);
        fin;
    fin;

    define-nueva-instruccion respuesta como inicio
        si junto-a-zumbador entonces inicio
            coge-zumbador;
            respuesta;
            deja-zumbador;
        fin sino inicio
            sur;
            mientras frente-libre hacer avanza;
            oeste;
            mientras frente-libre hacer avanza;
            mientras junto-a-zumbador hacer coge-zumbador;
        fin;
    fin;

    define-nueva-instruccion mayor como inicio
        norte;
        avanza;
        este;
        repetir 99 veces cuenta(0);
        respuesta;
        apagate;
    fin;

    define-nueva-instruccion siguiente como inicio
        si frente-libre entonces inicio
            avanza;
            si no-junto-a-zumbador entonces inicio
                este;
                avanza;
                mayor;
            fin;
        fin sino inicio
            mayor;
        fin;
    fin;

    define-nueva-instruccion copia(q) como inicio
        si junto-a-zumbador entonces inicio
            coge-zumbador;
            copia(sucede(q));
            deja-zumbador;
        fin sino inicio
            repetir q veces deja-zumbador;
            avanza;
        fin;
    fin;

    define-nueva-instruccion comparar2(x2) como inicio
        si junto-a-zumbador y no si-es-cero(x2) entonces inicio
            coge-zumbador;
            comparar2(precede(x2));
            deja-zumbador;
        fin sino inicio
            si junto-a-zumbador entonces inicio
                norte;
                avanza;
                copia(0);
                sur;
                avanza;
                avanza;
                este;
            fin;
        fin;
    fin;

    define-nueva-instruccion funcion(u) como inicio
        si frente-libre y junto-a-zumbador entonces inicio
            avanza;
            comparar2(u);
            funcion(u);
            avanza;
        fin sino inicio
            oeste;
        fin;
    fin;

    define-nueva-instruccion checa(x) como inicio
        si junto-a-zumbador entonces inicio
            coge-zumbador;
            checa(sucede(x));
        fin sino inicio
            repetir x veces deja-zumbador;
            este;
            funcion(x);
        fin;
    fin;

    define-nueva-instruccion mover como inicio
        si junto-a-zumbador entonces inicio
            coge-zumbador;
            mover;
            deja-zumbador;
        fin sino inicio
            sur;
            mientras frente-libre hacer avanza;
            oeste;
            mientras no-junto-a-zumbador hacer avanza;
            norte;
            avanza;
            oeste;
            mientras junto-a-zumbador hacer avanza;
        fin;
    fin;

    define-nueva-instruccion tomar como inicio
        norte;
        avanza;
        avanza;
        oeste;
        mientras frente-libre hacer avanza;
        este;
        repetir 99 veces cuenta(0);
        mover;
        deja-zumbador;
        sur;
        avanza;
        oeste;
    fin;

    inicia-ejecucion
        comienza;
        mientras algun-zumbador-en-la-mochila hacer inicio
            checa(0);
            tomar;
            siguiente;
        fin;
        apagate;
    termina-ejecucion
finalizar-programa
