iniciar-programa
    define-nueva-instruccion norte como mientras no-orientado-al-norte hacer gira-izquierda;
    define-nueva-instruccion este como mientras no-orientado-al-este hacer gira-izquierda;
    define-nueva-instruccion oeste como mientras no-orientado-al-oeste hacer gira-izquierda;
    define-nueva-instruccion sur como mientras no-orientado-al-sur hacer gira-izquierda;
    define-nueva-instruccion corre como mientras frente-libre hacer avanza;
    define-nueva-instruccion compara(x) como inicio
        repetir x veces si junto-a-zumbador entonces coge-zumbador;
        repetir x veces deja-zumbador;
    fin;
    define-nueva-instruccion mueve(x) como inicio
        si junto-a-zumbador entonces inicio
            coge-zumbador;
            mueve(sucede(x));
        fin sino inicio
            oeste;
            avanza;
            mientras junto-a-zumbador y frente-libre hacer avanza;
            este;
            si no-junto-a-zumbador entonces avanza;
            coge-zumbador;
            compara(x);
            deja-zumbador;
            este;
            avanza;
            mientras junto-a-zumbador hacer avanza;
            repetir x veces deja-zumbador;
        fin;
    fin;
    define-nueva-instruccion quita(x) como inicio
        si junto-a-zumbador y no si-es-cero(x) entonces inicio
            coge-zumbador;
            quita(precede(x));
            deja-zumbador;
        fin sino inicio
            si no-junto-a-zumbador entonces sur;
        fin;
    fin;
    define-nueva-instruccion cuantos(x) como inicio
        mientras junto-a-zumbador y no orientado-al-oeste hacer inicio
            norte;
            quita(x);
            si no-orientado-al-sur entonces inicio
                norte;
                avanza;
                oeste;
                mueve(0);
                sur;
                avanza;
            fin;
            este;
            si frente-libre entonces inicio
                avanza;
            fin sino inicio
                oeste;
            fin;
        fin;
    fin;
    define-nueva-instruccion lee(x) como inicio
        si junto-a-zumbador entonces inicio
            coge-zumbador;
            lee(sucede(x));
        fin sino inicio
            repetir x veces deja-zumbador;
            norte;
            repetir 2 veces inicio
                avanza;
                deja-zumbador;
            fin;
            sur;
            repetir 2 veces avanza;
            este;
            si frente-libre entonces inicio
                avanza;
            fin sino inicio
                oeste;
            fin;
            cuantos(x);
            norte;
            repetir 2 veces avanza;
            oeste;
            mientras no-junto-a-zumbador hacer avanza;
            coge-zumbador;
            sur;
            corre;
            oeste;
        fin;
    fin;
    define-nueva-instruccion responde(x) como inicio
        si junto-a-zumbador entonces inicio
            coge-zumbador;
            responde(sucede(x));
        fin sino inicio
            sur;
            avanza;
            mientras junto-a-zumbador hacer coge-zumbador;
            repetir x veces deja-zumbador;
        fin;
    fin;
    define-nueva-instruccion traslada(x) como inicio
        si no-orientado-al-este entonces inicio
            si junto-a-zumbador entonces inicio
                coge-zumbador;
                traslada(sucede(x));
            fin sino inicio
                oeste;
                si frente-libre entonces inicio
                    avanza;
                fin sino inicio
                    este;
                fin;
                repetir x veces si junto-a-zumbador entonces coge-zumbador;
                repetir x veces deja-zumbador;
                traslada(0);
            fin;
        fin sino inicio
            responde(0);
        fin;
    fin;
    inicia-ejecucion
        este;
        mientras junto-a-zumbador y frente-libre hacer avanza;
        oeste;
        si no-junto-a-zumbador entonces avanza;
        mientras no-orientado-al-este hacer inicio
            lee(0);
            si frente-libre entonces inicio
                avanza;
            fin sino inicio
                este;
            fin;
        fin;
        norte;
        avanza;
        este;
        mientras junto-a-zumbador y frente-libre hacer avanza;
        oeste;
        si no-junto-a-zumbador entonces avanza;
        traslada(0);
        apagate;
    termina-ejecucion
finalizar-programa
