iniciar-programa
    define-nueva-instruccion norte como mientras no orientado-al-norte hacer gira-izquierda;
    define-nueva-instruccion oeste como mientras no orientado-al-oeste hacer gira-izquierda;
    define-nueva-instruccion este como mientras no orientado-al-este hacer gira-izquierda;
    define-nueva-instruccion sur como mientras no orientado-al-sur hacer gira-izquierda;

    define-nueva-instruccion mayor(n) como inicio
        si junto-a-zumbador entonces inicio
            coge-zumbador;
            mayor(sucede(n));
        fin sino inicio
            sur;
            avanza;
            oeste;
            mientras junto-a-zumbador hacer avanza;
            norte;
            avanza;
            repetir n veces inicio
                si junto-a-zumbador entonces coge-zumbador;
            fin;
            repetir n veces deja-zumbador;
            este;
            mientras junto-a-zumbador hacer avanza;
            repetir n veces deja-zumbador;
            sur;
            avanza;
            este;
        fin;
    fin;

    define-nueva-instruccion dejar(n) como inicio
        si junto-a-zumbador entonces inicio
            coge-zumbador;
            dejar(n);
            si orientado-al-sur entonces inicio
                coge-zumbador;
            fin sino inicio
                deja-zumbador;
            fin;
        fin sino inicio
            repetir n veces deja-zumbador;
        fin;
    fin;

    define-nueva-instruccion checa(n) como inicio
        repetir n veces inicio
            si junto-a-zumbador y orientado-al-este entonces inicio
                coge-zumbador;
            fin sino inicio
                sur;
                deja-zumbador;
            fin;
        fin;
        si no junto-a-zumbador entonces sur;
        dejar(n);
        si orientado-al-este entonces inicio
            norte;
            avanza;
            mayor(0);
        fin sino inicio
            este;
        fin;
    fin;

    define-nueva-instruccion contar(n) como inicio
        si junto-a-zumbador entonces inicio
            coge-zumbador;
            contar(sucede(n));
        fin sino inicio
            este;
            avanza;
            mientras junto-a-zumbador hacer inicio
                checa(n);
                avanza;
            fin;
            oeste;
            avanza;
            mientras junto-a-zumbador hacer avanza;
            repetir n veces deja-zumbador;
            norte;
            avanza;
            deja-zumbador;
            sur;
            avanza;
            oeste;
        fin;
    fin;

    define-nueva-instruccion recoger(n) como inicio
        si junto-a-zumbador entonces inicio
            coge-zumbador;
            recoger(sucede(n));
        fin sino inicio
            avanza;
            si junto-a-zumbador entonces inicio
                recoger(0);
            fin sino inicio
                oeste;
                mientras frente-libre hacer avanza;
                sur;
                avanza;
                mientras junto-a-zumbador hacer coge-zumbador;
            fin;
            repetir n veces si junto-a-zumbador entonces coge-zumbador;
            repetir n veces deja-zumbador;
        fin;
    fin;

    inicia-ejecucion
        este;
        mientras junto-a-zumbador hacer avanza;
        oeste;
        si no junto-a-zumbador entonces avanza;
        mientras frente-libre hacer inicio
            contar(0);
            avanza;
        fin;
        contar(0);
        norte;
        avanza;
        este;
        recoger(0);
        apagate;
    termina-ejecucion
finalizar-programa
