iniciar-programa
    define-nueva-instruccion este como mientras no-orientado-al-este hacer gira-izquierda;
    define-nueva-instruccion oeste como mientras no-orientado-al-oeste hacer gira-izquierda;
    define-nueva-instruccion norte como mientras no-orientado-al-norte hacer gira-izquierda;
    define-nueva-instruccion sur como mientras no-orientado-al-sur hacer gira-izquierda;

    define-nueva-instruccion dejarmayor(n) como inicio
      si junto-a-zumbador y no si-es-cero(n) entonces inicio
        coge-zumbador;
        dejarmayor(precede(n));
        deja-zumbador;
      fin sino inicio
        repetir n veces deja-zumbador;
      fin;
    fin;

    define-nueva-instruccion compara2(n) como inicio
      si junto-a-zumbador y frente-libre y no-orientado-al-norte entonces inicio
        avanza;
        compara2(n);
        avanza;
      fin sino inicio
        si orientado-al-oeste y no-junto-a-zumbador entonces inicio
          este;
          avanza;
          norte;
          compara2(n);
          oeste;
          avanza;
          este;
        fin sino inicio
          dejarmayor(n);
          este;
        fin;
      fin;
    fin;

    define-nueva-instruccion compara(n) como inicio
      si junto-a-zumbador entonces inicio
        coge-zumbador;
        compara(sucede(n));
        deja-zumbador;
      fin sino inicio
        deja-zumbador;
        compara2(n);
        coge-zumbador;
      fin;
    fin;

    define-nueva-instruccion mayor(n) como inicio
      si junto-a-zumbador y no si-es-cero(n) entonces inicio
        coge-zumbador;
        mayor(precede(n));
        deja-zumbador;
      fin sino inicio
        si si-es-cero(n) y junto-a-zumbador entonces inicio
          norte;
          avanza;
          oeste;
          compara(1);
          sur;
          avanza;
          este;
        fin;
      fin;
    fin;

    define-nueva-instruccion grandes(n) como inicio
      norte;
      avanza;
      deja-zumbador;
      sur;
      avanza;
      este;
      avanza;
      mientras junto-a-zumbador hacer inicio
        mayor(n);
        avanza;
      fin;
    fin;

    define-nueva-instruccion recorre(n) como inicio
      si junto-a-zumbador entonces inicio
        coge-zumbador;
        recorre(sucede(n));
      fin sino inicio
        repetir n veces deja-zumbador;
        este;
        grandes(n);
      fin;
    fin;

    define-nueva-instruccion calcula(n) como inicio
      si frente-libre entonces inicio
        oeste;
        repetir n veces inicio
          si frente-libre entonces inicio
            avanza;
          fin sino inicio
            sur;
          fin;
        fin;
        si orientado-al-oeste entonces inicio
          recorre(0);
          calcula(sucede(n));
        fin;
      fin;
    fin;

    define-nueva-instruccion maximo(n) como inicio
      si junto-a-zumbador entonces inicio
        coge-zumbador;
        maximo(sucede(n));
      fin sino inicio
        avanza;
        si junto-a-zumbador entonces inicio
          dejarmayor(n);
        fin sino inicio
          oeste;
          mientras frente-libre hacer avanza;
          sur;
          avanza;
          mientras junto-a-zumbador hacer coge-zumbador;
          repetir n veces deja-zumbador;
        fin;
      fin;
    fin;

    define-nueva-instruccion maximos como inicio
      mientras orientado-al-este hacer maximo(0);
    fin;

    inicia-ejecucion
        este;
        mientras junto-a-zumbador hacer avanza;
        calcula(1);
        norte;
        avanza;
        este;
        maximos;
        este;
        apagate;
    termina-ejecucion
finalizar-programa

