iniciar-programa

    define-nueva-instruccion norte como
    inicio
        mientras no-orientado-al-norte hacer
        inicio
            gira-izquierda;
        fin;
    fin;

    define-nueva-instruccion sur como
    inicio
        mientras no-orientado-al-sur hacer
        inicio
            gira-izquierda;
        fin;
    fin;

    define-nueva-instruccion este como
    inicio
        mientras no-orientado-al-este hacer
        inicio
            gira-izquierda;
        fin;
    fin;

    define-nueva-instruccion oeste como
    inicio
        mientras no-orientado-al-oeste hacer
        inicio
            gira-izquierda;
        fin;
    fin;

    define-nueva-instruccion gira-derecha como
    inicio
        repetir 3 veces
        inicio
            gira-izquierda;
        fin;
    fin;

    define-nueva-instruccion gira-doble como
    inicio
        repetir 2 veces
        inicio
            gira-izquierda;
        fin;
    fin;

    define-nueva-instruccion camina como
    inicio
        mientras frente-libre hacer
        inicio
            avanza;
        fin;
    fin;

    define-nueva-instruccion parche como
    inicio
        si no-junto-a-zumbador entonces
        inicio
            gira-doble;
            si frente-libre entonces
            inicio
                avanza;
            fin;
        fin;
    fin;

    define-nueva-instruccion mover(x) como
    inicio
        si junto-a-zumbador entonces
        inicio
           avanza;
           mover(x);
           avanza;
        fin
        sino
        inicio
            norte;
            avanza;
            repetir x veces
            inicio
                si junto-a-zumbador entonces
                inicio
                    coge-zumbador;
                fin;
            fin;
            repetir x veces
            inicio
                deja-zumbador;
            fin;
            sur;
            avanza;
            este;
        fin;
    fin;

    define-nueva-instruccion llevar(x) como
    inicio
        si junto-a-zumbador entonces
        inicio
            coge-zumbador;
            llevar(sucede(x));
        fin
        sino
        inicio
            repetir x veces
            inicio
                deja-zumbador;
            fin;
            sur;
            avanza;
            oeste;
            mover(x);
        fin;
    fin;

    define-nueva-instruccion todo(x) como
    inicio
        repetir x veces
        inicio
            si junto-a-zumbador entonces
            inicio
                coge-zumbador;
            fin
            sino
            inicio
                repetir precede(x) veces
                inicio
                    deja-zumbador;
                fin;
                oeste;
            fin;
        fin;
        si (orientado-al-oeste o no-junto-a-zumbador) entonces
        inicio
            este;
            si no-junto-a-zumbador entonces
            inicio
                repetir x veces
                inicio
                    deja-zumbador;
                fin;
            fin;
        fin
        sino
        inicio
            repetir x veces
            inicio
                deja-zumbador;
            fin;
            norte;
            avanza;
            llevar(0);
        fin;
    fin;

    define-nueva-instruccion conseguir(x) como
    inicio
        si junto-a-zumbador entonces
        inicio
           coge-zumbador;
           conseguir(sucede(x));
        fin
        sino
        inicio
            si frente-libre entonces
            inicio
                avanza;
            fin;
            mientras (junto-a-zumbador y orientado-al-este) hacer
            inicio
                todo(x);
                si frente-libre entonces
                inicio
                avanza;
                fin
                sino
                inicio
                    oeste;
                fin;
            fin;
            este;
            parche;
            oeste;
            mientras junto-a-zumbador hacer
            inicio
                avanza;
            fin;
            repetir x veces
            inicio
                deja-zumbador;
            fin;
            norte;
            avanza;
            deja-zumbador;
            sur;
            avanza;
            oeste;
        fin;
    fin;

    define-nueva-instruccion busqueda como
    inicio
        si frente-libre entonces
        inicio
            avanza;
            este;
            conseguir(0);
        fin;
    fin;

    define-nueva-instruccion mayor(x) como
    inicio
        si junto-a-zumbador entonces
        inicio
            coge-zumbador;
            mayor(sucede(x));
        fin
        sino
        inicio
            avanza;
            repetir x veces
            inicio
                si junto-a-zumbador entonces
                inicio
                    coge-zumbador;
                fin;
            fin;
            repetir x veces
            inicio
                deja-zumbador;
            fin;
        fin;
    fin;

    define-nueva-instruccion ultima como
    inicio
        si junto-a-zumbador entonces
        inicio
            coge-zumbador;
            ultima;
            deja-zumbador;
        fin
        sino
        inicio
            avanza;
            mientras junto-a-zumbador hacer
            inicio
                coge-zumbador;
            fin;
        fin;
    fin;

    inicia-ejecucion
    este;
    mientras (junto-a-zumbador y frente-libre) hacer
    inicio
        avanza;
    fin;
    parche;
    norte;
    avanza;
    deja-zumbador;
    sur;
    avanza;
    oeste;
    mientras frente-libre hacer
    inicio
        busqueda;
    fin;
    sur;
    camina;
    oeste;
    camina;
    norte;
    avanza;
    este;
    mientras (junto-a-zumbador y frente-libre) hacer
    inicio
        avanza;
    fin;
    parche;
    oeste;
    mientras frente-libre hacer
    inicio
        mayor(0);
    fin;
    sur;
    ultima;
    apagate;
    termina-ejecucion
finalizar-programa
