iniciar-programa
define-nueva-instruccion gira(n) como inicio
    repetir n veces gira-izquierda;
fin;
define-nueva-instruccion camino como inicio
    si frente-libre entonces inicio
        avanza;
        camino;
        si orientado-al-norte y frente-bloqueado entonces gira(3);
        si orientado-al-oeste entonces inicio
            gira(1);
            mientras frente-libre hacer avanza;
            gira(2);
        fin;
        si frente-libre entonces avanza;
    fin;
fin;
define-nueva-instruccion medio como inicio
    si frente-libre entonces inicio
        avanza;
        si frente-libre entonces inicio
        avanza;
        medio;
        si frente-bloqueado entonces gira(2);
        avanza;
        fin;
    fin;
fin;
define-nueva-instruccion lado(n) como inicio
    si frente-libre y junto-a-zumbador entonces avanza;
    si no-junto-a-zumbador entonces inicio
        repetir n veces deja-zumbador;
    fin;
    si frente-libre entonces lado(sucede(n));
fin;
define-nueva-instruccion cubo(n) como inicio
    si junto-a-zumbador entonces inicio
       coge-zumbador;
       cubo(sucede(n));
    fin
    sino inicio
        si si-es-cero(precede(n)) entonces inicio
            deja-zumbador;
            apagate;
        fin;
        repetir n veces deja-zumbador;
        repetir precede(n) veces inicio
            avanza;
            repetir n veces deja-zumbador;
        fin;
        gira(3);
        repetir 3 veces inicio
            repetir 2 veces inicio
                repetir precede(n) veces inicio
                    avanza;
                    repetir n veces deja-zumbador;
                fin;
            fin;
            gira(3);
        fin;
        repetir precede(n) veces inicio
            avanza;
            si no-junto-a-zumbador entonces inicio
                repetir n veces deja-zumbador;
            fin;
        fin;
    fin;
fin;
inicia-ejecucion
    mientras no-orientado-al-norte hacer gira(1);
    camino;
    si frente-libre entonces inicio
       gira(2);
    fin
    sino inicio
        gira(2);
        camino;
        gira(2);
    fin;
    medio;
    gira(3);
    si orientado-al-este entonces inicio
           mientras frente-libre hacer avanza;
           gira(2);
       fin;
    medio;
    mientras no-orientado-al-oeste hacer gira(1);
    lado(1);
    gira(3);
    mientras junto-a-zumbador hacer inicio
    cubo(0);
    gira(3);
    avanza;
    gira(1);
    fin;

        apagate;
    termina-ejecucion
finalizar-programa
