iniciar-programa
    define-nueva-instruccion gira(n) como repetir n veces gira-izquierda;

    define-nueva-instruccion Ini como inicio
        mientras no-orientado-al-oeste hacer gira-izquierda;
        mientras frente-libre hacer avanza;
        gira(1);
        mientras frente-libre hacer avanza;
        gira(2);
    fin;

    define-nueva-instruccion distancia(x) como inicio
        si frente-libre entonces inicio
            avanza;
            distancia(sucede(x));
        fin sino inicio
            Ini;
            repetir x veces deja-zumbador;
        fin;
    fin;

    define-nueva-instruccion mitad(x) como inicio
        si junto-a-zumbador entonces inicio
            coge-zumbador;
            si junto-a-zumbador entonces coge-zumbador;
            mitad(sucede(x));
        fin sino inicio
            repetir x veces avanza;
            gira(3);
            repetir x veces avanza;
            gira(3);
        fin;
    fin;

    define-nueva-instruccion paridad(beepers) como inicio
        si junto-a-zumbador entonces inicio
            coge-zumbador;
            si junto-a-zumbador entonces inicio
                coge-zumbador;
                paridad(sucede(sucede(beepers)));
            fin sino inicio
                (*Es impar*)
                repetir beepers veces deja-zumbador;
            fin;
        fin sino inicio
            (*Es par*)
            repetir beepers veces deja-zumbador;
        fin;
    fin;

    define-nueva-instruccion compara(menor) como inicio
        si no(si-es-cero(menor)) entonces inicio
            si frente-libre entonces inicio
                avanza;
                compara(precede(menor));
            fin sino inicio
                (*HORIZONTAL*)
                gira(2);
                distancia(0);
                paridad(0);
                mitad(0);
            fin;
        fin sino inicio
            (*VERTICAL*)
            gira(3);
            distancia(0);
            paridad(0);
            mitad(0);
        fin;
    fin;

    define-nueva-instruccion centro(menor) como inicio
        si frente-libre entonces inicio
            avanza;
            centro(sucede(menor));
        fin sino inicio
            gira(3);
            compara(menor);
        fin;
    fin;

    define-nueva-instruccion cubos(tamanio) como inicio
        si si-es-cero(precede(tamanio)) entonces inicio
            deja-zumbador;
            si frente-libre entonces inicio
                avanza;
                gira(3);
                avanza;
                gira(3);
                cubos(sucede(tamanio));
            fin sino inicio
                apagate;
            fin;
        fin sino inicio
            repetir 4 veces inicio
                repetir tamanio veces deja-zumbador;
                avanza;
                gira(3);
                avanza;
                gira(1);
                mientras junto-a-zumbador hacer avanza;
                gira(1);
                avanza;
                gira(2);
            fin;
            repetir 4 veces inicio
                avanza;
                mientras no-junto-a-zumbador hacer inicio
                    repetir tamanio veces deja-zumbador;
                    avanza;
                fin;
                gira(3);
            fin;
            gira(2);
            si frente-libre entonces inicio
                avanza;
                gira(3);
                avanza;
                gira(3);
                cubos(sucede(tamanio));
            fin sino inicio
                apagate;
            fin;
        fin;
    fin;

    inicia-ejecucion
        mientras no-orientado-al-norte hacer gira-izquierda;
        centro(0);
        cubos(1);
        apagate;
    termina-ejecucion
finalizar-programa
