iniciar-programa
    define-nueva-instruccion media-vuelta como
        repetir 2 veces
            gira-izquierda;
    define-nueva-instruccion gira-derecha como
        repetir 3 veces
            gira-izquierda;
    define-nueva-instruccion cuenta como
        si frente-libre  entonces inicio
            avanza;
            cuenta;
            si frente-libre entonces
                avanza
            sino
                mientras no-orientado-al-sur hacer
                    gira-izquierda;
        fin
        sino inicio
            media-vuelta;
            mientras frente-libre hacer
                avanza;
            gira-izquierda;
        fin;
      define-nueva-instruccion cubo(x) como
      si no-junto-a-zumbador entonces inicio
          gira-izquierda;
          repetir 4 veces inicio
              si no-junto-a-zumbador entonces inicio
                  repetir x veces
                      deja-zumbador;
                  deja-zumbador;
              fin;
              repetir x veces inicio
                  avanza;
                  repetir x veces
                      deja-zumbador;
                  deja-zumbador;
                  avanza;
                  si no-junto-a-zumbador entonces inicio
                      repetir x veces
                          deja-zumbador;
                      deja-zumbador;
                  fin;
              fin;
              gira-izquierda;
          fin;
          cubo(x);
    fin
    sino inicio
        mientras no-orientado-al-oeste hacer
            gira-izquierda;
        si frente-libre y derecha-libre entonces inicio
            avanza;
            gira-izquierda;
            si frente-libre entonces inicio
                avanza;
                cubo(sucede(x));
            fin;
        fin;
    fin;
    define-nueva-instruccion mitad(x) como
        si frente-libre entonces inicio
            avanza;
            si frente-libre entonces inicio
                avanza;
                mitad(sucede(x));
            fin
            sino
                mitad(x);
         fin
         sino inicio
             media-vuelta;
             mientras frente-libre hacer
                 avanza;
             mientras no-orientado-al-este hacer
                 gira-izquierda;
            repetir x veces
               avanza;
            gira-izquierda;
            repetir x veces
                avanza;
        fin;



    inicia-ejecucion
        mientras no-orientado-al-norte hacer
            gira-izquierda;
        cuenta;
        si orientado-al-sur entonces inicio
            gira-derecha;
            mientras frente-libre hacer
                avanza;
            media-vuelta;
        fin
        sino inicio
            media-vuelta;
            mientras frente-libre hacer
                avanza;
            gira-derecha;
        fin;
            mitad(0);
        si frente-libre y derecha-libre entonces
            cubo(0)
        sino
            deja-zumbador;
        apagate;
    termina-ejecucion
finalizar-programa
