iniciar-programa
    define-nueva-instruccion norte como inicio
        mientras no-orientado-al-norte hacer inicio
            gira-izquierda;
        fin;
    fin;

    define-nueva-instruccion oeste como inicio
        mientras no-orientado-al-oeste hacer inicio
            gira-izquierda;
        fin;
    fin;

    define-nueva-instruccion sur como inicio
        mientras no-orientado-al-sur hacer inicio
            gira-izquierda;
        fin;
    fin;

    define-nueva-instruccion este como inicio
        mientras no-orientado-al-este hacer inicio
            gira-izquierda;
        fin;
    fin;

    define-nueva-instruccion ir11 como inicio
        sur;
        mientras frente-libre hacer inicio
            avanza;
        fin;
        oeste;
        mientras frente-libre hacer inicio
            avanza;
        fin;
    fin;

    define-nueva-instruccion busqueda como inicio
        deja-zumbador;
        norte;
        si frente-libre entonces inicio
            avanza;
            si no-junto-a-zumbador entonces inicio
                busqueda;
            fin;
            sur;
            avanza;
        fin;
        oeste;
        si frente-libre entonces inicio
            avanza;
            si no-junto-a-zumbador entonces inicio
                busqueda;
            fin;
            este;
            avanza;
        fin;
        sur;
        si frente-libre entonces inicio
            avanza;
            si no-junto-a-zumbador entonces inicio
                busqueda;
            fin;
            norte;
            avanza;
        fin;
        este;
        si frente-libre entonces inicio
            avanza;
            si no-junto-a-zumbador entonces inicio
                busqueda;
            fin;
            oeste;
            avanza;
        fin;
    fin;

    define-nueva-instruccion camina como inicio
        si frente-libre entonces inicio
            avanza;
        fin sino inicio
            si orientado-al-oeste entonces inicio
                norte;
                si frente-libre entonces inicio
                    avanza;
                    este;
                fin;
            fin sino inicio
                norte;
                si frente-libre entonces inicio
                    avanza;
                    oeste;
                fin;
            fin;
        fin;
    fin;

    define-nueva-instruccion infeccion (n) como inicio
        si junto-a-zumbador y no-orientado-al-norte entonces inicio
            camina;
            infeccion (n);
        fin sino inicio
            si orientado-al-norte entonces inicio
                ir11;
                mientras junto-a-zumbador hacer inicio
                    coge-zumbador;
                fin;
                repetir n veces inicio
                    deja-zumbador;
                fin;
                apagate;
            fin sino inicio
                si orientado-al-oeste entonces inicio
                    busqueda;
                    oeste;
                fin sino inicio
                    busqueda;
                    este;
                fin;
                infeccion (sucede (n));
            fin;
        fin;
    fin;
    inicia-ejecucion
        busqueda;
        ir11;
        este;
        infeccion (0);
        apagate;
    termina-ejecucion
finalizar-programa
