iniciar-programa
define-nueva-instruccion gira(n) como inicio
    repetir n veces inicio
        gira-izquierda;
    fin;
fin;
define-nueva-instruccion norte como inicio
    mientras no-orientado-al-norte hacer inicio
        gira(1);
    fin;
fin;
define-nueva-instruccion sur como inicio
    mientras no-orientado-al-sur hacer inicio
        gira(1);
    fin;
fin;
define-nueva-instruccion este como inicio
    mientras no-orientado-al-este hacer inicio
        gira(1);
    fin;
fin;
define-nueva-instruccion oeste como inicio
    mientras no-orientado-al-oeste hacer inicio
        gira(1);
    fin;
fin;
define-nueva-instruccion visita como inicio
    deja-zumbador;

    norte;
    si frente-libre entonces inicio
        avanza;
        si no-junto-a-zumbador entonces inicio
            visita;
        fin;
        sur;
        avanza;
    fin;

    sur;
    si frente-libre entonces inicio
        avanza;
        si no-junto-a-zumbador entonces inicio
            visita;
        fin;
        norte;
        avanza;
    fin;

    este;
    si frente-libre entonces inicio
        avanza;
        si no-junto-a-zumbador entonces inicio
            visita;
        fin;
        oeste;
        avanza;
    fin;

    oeste;
    si frente-libre entonces inicio
        avanza;
        si no-junto-a-zumbador entonces inicio
            visita;
        fin;
        este;
        avanza;
    fin;
fin;
define-nueva-instruccion ir11 como inicio
    oeste;
    mientras frente-libre hacer inicio
        avanza;
    fin;
    sur;
    mientras frente-libre hacer inicio
        avanza;
    fin;
    norte;
fin;
define-nueva-instruccion busquedad(x) como inicio
    norte;
    si junto-a-zumbador y frente-libre entonces inicio
        avanza;
        busquedad(x);
    fin sino inicio
        si junto-a-zumbador y frente-bloqueado y derecha-libre entonces inicio
            gira(2);
            mientras frente-libre hacer inicio
                avanza;
            fin;
            gira(1);
            avanza;
            gira(1);
            busquedad(x);
        fin sino inicio
            si no-junto-a-zumbador entonces inicio
                visita;
                busquedad(sucede(x));
            fin sino inicio
                si junto-a-zumbador y frente-bloqueado y derecha-bloqueada entonces inicio
                    ir11;
                    coge-zumbador;
                    repetir x veces inicio
                        deja-zumbador;
                    fin;
                fin;    
            fin;
        fin;
    fin;
fin;

    inicia-ejecucion
        ir11;
        visita;
        norte;
        busquedad(0);
        apagate;
    termina-ejecucion
finalizar-programa
