iniciar-programa
define-nueva-instruccion norte como mientras no-orientado-al-norte hacer gira-izquierda;
define-nueva-instruccion sur como mientras no-orientado-al-sur hacer gira-izquierda;
define-nueva-instruccion este como mientras no-orientado-al-este hacer gira-izquierda;
define-nueva-instruccion oeste como mientras no-orientado-al-oeste hacer gira-izquierda;

define-nueva-instruccion ir1-1 como
    inicio
        oeste;
    mientras frente-libre hacer avanza;
        sur;
    mientras frente-libre hacer avanza;
    fin;

define-nueva-instruccion camina como
    inicio
    si frente-libre entonces
        inicio
            avanza;
        fin
    sino
        inicio
            oeste;
        mientras frente-libre hacer avanza;
            norte;
        si frente-libre entonces
            inicio
                avanza;
                este;
            fin;
        fin;
    fin;

define-nueva-instruccion LlenarDeUnos como
    inicio
    si no-junto-a-zumbador entonces
        inicio
            deja-zumbador;
            norte;
        si frente-libre entonces
            inicio
                avanza;
                LlenarDeUnos;
                sur;
                avanza;
            fin;
            sur;
        si frente-libre entonces
            inicio
                avanza;
                LlenarDeUnos;
                norte;
                avanza;
            fin;
            este;
        si frente-libre entonces
            inicio
                avanza;
                LlenarDeUnos;
                oeste;
                avanza;
            fin;
            oeste;
        si frente-libre entonces
            inicio
                avanza;
                LlenarDeUnos;
                este;
                avanza;
            fin;
        fin;
    fin;

define-nueva-instruccion RealizaBusqueda como
    inicio
        ir1-1;
        LlenarDeUnos;
        este;
    mientras no-orientado-al-norte hacer
        inicio
            camina;
        si no junto-a-zumbador entonces
            inicio
                LlenarDeUnos;
                ir1-1;
                deja-zumbador;
                este;
            fin;
        fin;
        ir1-1;
        coge-zumbador;
    fin;


    inicia-ejecucion
        RealizaBusqueda;
        apagate;
    termina-ejecucion
finalizar-programa
