iniciar-programa
define-nueva-instruccion este como mientras no-orientado-al-este hacer gira-izquierda;
define-nueva-instruccion oeste como mientras no-orientado-al-oeste hacer gira-izquierda;
define-nueva-instruccion norte como mientras no-orientado-al-norte hacer gira-izquierda;
define-nueva-instruccion sur como mientras no-orientado-al-sur hacer gira-izquierda;
define-nueva-instruccion llena como inicio
    norte;
    si no-junto-a-zumbador entonces deja-zumbador;
    si frente-libre entonces inicio
        avanza;
        si no-junto-a-zumbador entonces llena;
        sur;
        avanza;
    fin;
    oeste;
    si frente-libre entonces inicio
        avanza;
        si no-junto-a-zumbador entonces llena;
        este;
        avanza;
    fin;
    sur;
    si frente-libre entonces inicio
        avanza;
        si no-junto-a-zumbador entonces llena;
        norte;
        avanza;
    fin;
    este;
    si frente-libre entonces inicio
        avanza;
        si no-junto-a-zumbador entonces llena;
        oeste;
        avanza;
    fin;
    este;
fin;
define-nueva-instruccion ir11 como inicio
    oeste;
    mientras frente-libre hacer avanza;
    sur;
    mientras frente-libre hacer avanza;
fin;
define-nueva-instruccion cuenta(n) como inicio
    si no-junto-a-zumbador entonces inicio
        llena;
        cuenta(sucede(n));
    fin sino inicio
        mientras junto-a-zumbador hacer inicio
            si frente-bloqueado entonces inicio
                oeste;
                mientras frente-libre hacer avanza;
                norte;
                si frente-libre entonces inicio
                    avanza;
                    este;
                fin sino inicio
                    ir11;
                    mientras junto-a-zumbador hacer coge-zumbador;
                    repetir n veces deja-zumbador;
                    apagate;
                fin;
            fin sino avanza;
        fin;
        si no-junto-a-zumbador entonces cuenta(n);
    fin;
fin;
    inicia-ejecucion
    oeste;
    mientras frente-libre hacer avanza;
    sur;
    mientras frente-libre hacer avanza;
    llena;
    este;
    cuenta(0);
        apagate;
    termina-ejecucion
finalizar-programa
