iniciar-programa
    define-nueva-instruccion este como mientras no orientado-al-este hacer gira-izquierda;
    define-nueva-instruccion norte como mientras no orientado-al-norte hacer gira-izquierda;
    define-nueva-instruccion oeste como mientras no orientado-al-oeste hacer gira-izquierda;
    define-nueva-instruccion sur como mientras no orientado-al-sur hacer gira-izquierda;
    define-nueva-instruccion avanzar como mientras frente-libre hacer avanza;
    define-nueva-instruccion cubetita como inicio
        deja-zumbador;
        norte;
        si frente-libre entonces inicio
            avanza;
            si no junto-a-zumbador entonces inicio
                cubetita;
            fin;
            sur;
            avanza;
        fin;
        sur;
        si frente-libre entonces inicio
            avanza;
            si no junto-a-zumbador entonces inicio
                cubetita;
            fin;
            norte;
            avanza;
         fin;
         este;
         si frente-libre entonces inicio
             avanza;
             si no junto-a-zumbador entonces inicio
                 cubetita;
             fin;
             oeste;
             avanza;
         fin;
         oeste;
         si frente-libre entonces inicio
             avanza;
             si no junto-a-zumbador entonces inicio
                 cubetita;
             fin;
             este;
             avanza;
          fin;
     fin;
     define-nueva-instruccion vacuna(n) como inicio
         si no junto-a-zumbador entonces inicio
             cubetita;
             vacuna(sucede(n));
         fin sino inicio
             si no orientado-al-norte o frente-libre entonces inicio
                 este;
                 si frente-libre entonces inicio
                     avanza;
                     vacuna(0);
                 fin sino inicio
                     oeste;
                     avanzar;
                     norte;
                     si frente-libre entonces inicio
                         avanza;
                         este;
                         vacuna(0);
                     fin sino inicio
                         sur;
                         avanzar;
                         mientras junto-a-zumbador hacer coge-zumbador;
                    fin;
                 fin;
            fin sino inicio
                sur;
                avanzar;
                mientras junto-a-zumbador hacer coge-zumbador;
            fin;
            repetir n veces deja-zumbador;
         fin;
    fin;
    inicia-ejecucion
        sur;
        avanzar;
        oeste;
        avanzar;
        cubetita;
        este;
        vacuna(0);
        apagate;
    termina-ejecucion
finalizar-programa
