iniciar-programa
    define-nueva-instruccion norte como mientras no-orientado-al-norte hacer gira-izquierda;
    define-nueva-instruccion sur como mientras no-orientado-al-sur hacer gira-izquierda;
    define-nueva-instruccion este como mientras no-orientado-al-este hacer gira-izquierda;
    define-nueva-instruccion oeste como mientras no-orientado-al-oeste hacer gira-izquierda;

    define-nueva-instruccion skina como
    inicio
        sur;
        mientras frente-libre hacer avanza;
        oeste;
        mientras frente-libre hacer avanza;
    fin;

    define-nueva-instruccion camina como
    inicio
        si frente-libre entonces
        inicio
            avanza;
        fin sino
        inicio
            oeste;
            mientras frente-libre hacer avanza;
            norte;
            avanza;
            este;
        fin;
    fin;

    define-nueva-instruccion llenar como
    inicio
        si no-junto-a-zumbador entonces
        inicio
            deja-zumbador;
            norte;
            si frente-libre entonces
            inicio
                avanza;
                llenar;
                sur;
                avanza;
            fin;
            sur;
            si frente-libre entonces
            inicio
                avanza;
                llenar;
                norte;
                avanza;
            fin;
            este;
            si frente-libre entonces
            inicio
                avanza;
                llenar;
                oeste;
                avanza;
            fin;
            oeste;
            si frente-libre entonces
            inicio
                avanza;
                llenar;
                este;
                avanza;
            fin;
        fin;
    fin;

    define-nueva-instruccion globulos como
    inicio
        skina;
        llenar;
        este;
        mientras izquierda-libre hacer
        inicio
            camina;
            si no-junto-a-zumbador entonces
            inicio
                llenar;
                skina;
                deja-zumbador;
                este;
            fin;
        fin;
        skina;
        coge-zumbador;
    fin;

    inicia-ejecucion
        globulos;
        apagate;
    termina-ejecucion
finalizar-programa
