iniciar-programa
define-nueva-instruccion norte como mientras no orientado-al-norte hacer gira-izquierda;
define-nueva-instruccion sur como mientras no orientado-al-sur hacer gira-izquierda;
define-nueva-instruccion este como mientras no orientado-al-este hacer gira-izquierda;
define-nueva-instruccion oeste como mientras no orientado-al-oeste hacer gira-izquierda;

define-nueva-instruccion ir11 como
  inicio
    sur;
    mientras frente-libre hacer avanza;
    oeste;
    mientras frente-libre hacer avanza;
  fin;

define-nueva-instruccion camina como
  inicio
    si frente-libre entonces avanza sino
      inicio
        oeste;
        mientras frente-libre hacer avanza;
        norte;
        avanza;
        este;
      fin;
  fin;

define-nueva-instruccion llenado como
  inicio
    si no junto-a-zumbador entonces
      inicio
        deja-zumbador;
        norte;
        si frente-libre entonces
          inicio
           avanza;
           llenado;
           sur;
           avanza;
          fin;

         sur;
        si frente-libre entonces
          inicio
           avanza;
           llenado;
           norte;
           avanza;
          fin;

         este;
        si frente-libre entonces
          inicio
           avanza;
           llenado;
           oeste;
           avanza;
          fin;

         oeste;
        si frente-libre entonces
          inicio
           avanza;
           llenado;
           este;
           avanza;
          fin;
      fin;
  fin;
    inicia-ejecucion
         ir11;
         llenado;
         este;
         mientras izquierda-libre o frente-libre hacer
           inicio
             camina;
              si no junto-a-zumbador entonces
                inicio
                  llenado;
                  ir11;
                  deja-zumbador;
                  este;
                fin;
           fin;
           ir11;
           coge-zumbador;
        apagate;
    termina-ejecucion
finalizar-programa
