iniciar-programa
   define-nueva-instruccion norte como mientras no orientado-al-norte hacer gira-izquierda;
   define-nueva-instruccion sur como mientras no orientado-al-sur hacer gira-izquierda;
   define-nueva-instruccion este como mientras no orientado-al-este hacer gira-izquierda;
   define-nueva-instruccion oeste como mientras no orientado-al-oeste hacer gira-izquierda;
   define-nueva-instruccion ir como inicio
       sur;
       mientras frente-libre hacer avanza;
       oeste;
       mientras frente-libre hacer avanza;
   fin;
   define-nueva-instruccion llenarunos como inicio
      si no junto-a-zumbador entonces inicio
         deja-zumbador;
         norte;
         si frente-libre entonces inicio
            avanza;
            llenarunos;
            sur;
            avanza;
         fin;
         este;
         si frente-libre entonces inicio
            avanza;
            llenarunos;
            oeste;
            avanza;
         fin;
         sur;
         si frente-libre entonces inicio
            avanza;
            llenarunos;
            norte;
            avanza;
         fin;
         oeste;
         si frente-libre entonces inicio
            avanza;
            llenarunos;
            este;
            avanza;
         fin;
      fin;
   fin;
   define-nueva-instruccion camina como inicio
      si frente-libre entonces inicio
         avanza;
      fin sino inicio
         oeste;
         mientras frente-libre hacer avanza;
         norte;
         avanza;
         este;
      fin;
   fin;
    inicia-ejecucion
    ir;
    llenarunos;
    este;
    mientras izquierda-libre hacer inicio
       si junto-a-zumbador entonces inicio
          camina;
       fin sino inicio
          llenarunos;
          ir;
          deja-zumbador;
          este;
       fin;
    fin;
    ir;
    coge-zumbador;
        apagate;
    termina-ejecucion
finalizar-programa
