iniciar-programa
define-nueva-instruccion norte como mientras no-orientado-al-norte hacer gira-izquierda;
define-nueva-instruccion este como mientras no-orientado-al-este hacer gira-izquierda;
define-nueva-instruccion sur como mientras no-orientado-al-sur hacer gira-izquierda;
define-nueva-instruccion oeste como mientras no-orientado-al-oeste hacer gira-izquierda;
define-nueva-instruccion pon como inicio
    sur;
    mientras frente-libre hacer avanza;
    oeste;
    mientras frente-libre hacer avanza;
    este;
    mientras izquierda-libre hacer inicio
        mientras frente-libre hacer inicio
            si no junto-a-zumbador entonces inicio
                deja-zumbador;
                deja-zumbador;
            fin;
            avanza;
            si no junto-a-zumbador entonces inicio
                deja-zumbador;
                deja-zumbador;
            fin;
        fin;
        oeste;
        mientras frente-libre hacer avanza;
        norte;
        avanza;
        este;
    fin;
    mientras frente-libre hacer inicio
        si no junto-a-zumbador entonces inicio
            deja-zumbador;
            deja-zumbador;
        fin;
        avanza;
        si no junto-a-zumbador entonces inicio
            deja-zumbador;
            deja-zumbador;
        fin;
    fin;
    sur;
    mientras frente-libre hacer avanza;
    oeste;
    mientras frente-libre hacer avanza;
    este;
fin;
define-nueva-instruccion quita como inicio
    si junto-a-zumbador entonces inicio
        coge-zumbador;
        si junto-a-zumbador entonces inicio
            coge-zumbador;
            repetir 4 veces inicio
                si frente-libre entonces inicio
                    avanza;
                    quita;
                    gira-izquierda;
                    gira-izquierda;
                    avanza;
                    gira-izquierda;
                    gira-izquierda;
                fin;
                gira-izquierda;
            fin;
        fin sino inicio
            deja-zumbador;
        fin;
    fin;
fin;
define-nueva-instruccion recorre(n) como inicio
    si frente-libre y izquierda-libre entonces inicio
        si junto-a-zumbador entonces inicio
            coge-zumbador;
            si junto-a-zumbador entonces inicio
                deja-zumbador;
                quita;
                recorre(sucede(n));
            fin sino inicio
                deja-zumbador;
                avanza;
                recorre(n);
            fin;
        fin sino inicio
            avanza;
            recorre(n);
        fin;
    fin sino inicio
        oeste;
        mientras frente-libre hacer avanza;
        norte;
        si frente-bloqueado entonces inicio
            sur;
            mientras frente-libre hacer avanza;
            repetir n veces deja-zumbador;
            coge-zumbador;
            apagate;
        fin sino inicio
            avanza;
            este;
            recorre(n);
        fin;
    fin;
fin;
    inicia-ejecucion
        oeste;
        mientras frente-libre hacer avanza;
        sur;
        mientras frente-libre hacer avanza;
        este;
        pon;
        recorre(0);

        apagate;
    termina-ejecucion
finalizar-programa
