iniciar-programa
    define-nueva-instruccion este como mientras no-orientado-al-este hacer gira-izquierda;
    define-nueva-instruccion oeste como mientras no-orientado-al-oeste hacer gira-izquierda;
    define-nueva-instruccion norte como mientras no-orientado-al-norte hacer gira-izquierda;
    define-nueva-instruccion sur como mientras no-orientado-al-sur hacer gira-izquierda;
    define-nueva-instruccion ir11 como inicio
        sur;
        mientras frente-libre hacer inicio
            avanza;
        fin;
        oeste;
        mientras frente-libre hacer inicio
            avanza;
        fin;
        este;
    fin;
    define-nueva-instruccion llenar como inicio
        mientras no-junto-a-zumbador hacer inicio
            deja-zumbador;
            este;
            si frente-libre entonces inicio
                avanza;
                llenar;
                oeste;
                avanza;
            fin;
            oeste;
            si frente-libre entonces inicio
                avanza;
                llenar;
                este;
                avanza;
            fin;
            norte;
            si frente-libre entonces inicio
                avanza;
                llenar;
                sur;
                avanza;
            fin;
            sur;
            si frente-libre entonces inicio
                avanza;
                llenar;
                norte;
                avanza;
            fin;
        fin;
    fin;
    define-nueva-instruccion camina como inicio
        si frente-libre entonces inicio
            avanza;
        fin
        sino inicio
            si orientado-al-este entonces inicio
                norte;
                si frente-libre entonces inicio
                    avanza;
                    oeste;
                fin;
            fin
            sino inicio
                norte;
                si frente-libre entonces inicio
                    avanza;
                    este;
                fin;
            fin;
        fin;
    fin;
    define-nueva-instruccion contar como inicio
        ir11;
        deja-zumbador;
        este;
    fin;

    inicia-ejecucion
        ir11;
        mientras no-orientado-al-norte hacer inicio
            si no-junto-a-zumbador entonces inicio
                llenar;
                contar;
                este;
            fin;
            camina;
        fin;
        ir11;
        coge-zumbador;
        coge-zumbador;
        apagate;
    termina-ejecucion
finalizar-programa
