iniciar-programa
    define-nueva-instruccion norte como mientras no orientado-al-norte hacer gira-izquierda;
    define-nueva-instruccion oeste como mientras no orientado-al-oeste hacer gira-izquierda;
    define-nueva-instruccion este como mientras no orientado-al-este hacer gira-izquierda;
    define-nueva-instruccion sur como mientras no orientado-al-sur hacer gira-izquierda;

    define-nueva-instruccion marcar como inicio
        si no junto-a-zumbador entonces inicio
            deja-zumbador;
            norte;
            si frente-libre entonces inicio
                avanza;
                marcar;
                sur;
                avanza;
            fin;
            este;
            si frente-libre entonces inicio
                avanza;
                marcar;
                oeste;
                avanza;
            fin;
            sur;
            si frente-libre entonces inicio
                avanza;
                marcar;
                norte;
                avanza;
            fin;
            oeste;
            si frente-libre entonces inicio
                avanza;
                marcar;
                este;
                avanza;
            fin;
        fin;
    fin;

    define-nueva-instruccion ir11 como inicio
        oeste;
        mientras frente-libre hacer inicio
            avanza;
        fin;
        sur;
        mientras frente-libre hacer inicio
            avanza;
        fin;
        este;
    fin;

    define-nueva-instruccion avanzar como inicio
        si frente-libre entonces inicio
            avanza;
        fin sino inicio
            norte;
            avanza;
            oeste;
            mientras frente-libre hacer inicio
                avanza;
            fin;
            este;
        fin;
    fin;
    define-nueva-instruccion globulos-rojos(n) como inicio
        si frente-libre o izquierda-libre entonces inicio
            avanzar;
            si no junto-a-zumbador entonces inicio
                marcar;
                globulos-rojos(sucede(n));
            fin sino inicio
                globulos-rojos(n);
            fin;
        fin sino inicio
            ir11;
            repetir n veces deja-zumbador;
            coge-zumbador;
        fin;
    fin;

    inicia-ejecucion
        ir11;
        marcar;
        este;
        globulos-rojos(0);
        apagate;
    termina-ejecucion
finalizar-programa
