iniciar-programa
    define-nueva-instruccion gira (n) como inicio
        repetir n veces
            gira-izquierda;
    fin;
    define-nueva-instruccion norte como inicio
        mientras no-orientado-al-norte hacer
            gira (1);
    fin;
    define-nueva-instruccion este como inicio
        mientras no-orientado-al-este hacer
            gira (1);
    fin;
    define-nueva-instruccion sur como inicio
        mientras no-orientado-al-sur hacer
            gira (1);
    fin;
    define-nueva-instruccion oeste como inicio
        mientras no-orientado-al-oeste hacer
            gira (1);
    fin;
    define-nueva-instruccion orienta como inicio
        sur;
        mientras frente-libre hacer
            avanza;
        oeste;
        mientras frente-libre hacer
            avanza;
        norte;
    fin;
    define-nueva-instruccion rellena como inicio
        si no-junto-a-zumbador entonces inicio
            deja-zumbador;
            norte;
            si frente-libre entonces inicio
                avanza;
                rellena;
                sur;
                avanza;
            fin;
            este;
            si frente-libre entonces inicio
                avanza;
                rellena;
                oeste;
                avanza;
            fin;
            sur;
            si frente-libre entonces inicio
                avanza;
                rellena;
                norte;
                avanza;
            fin;
            oeste;
            si frente-libre entonces inicio
                avanza;
                rellena;
                este;
                avanza;
            fin;
        fin;
    fin;
    define-nueva-instruccion recore (n) como inicio
        si no-junto-a-zumbador entonces inicio
            rellena;
            orienta;
            recore (sucede(n));
        fin
        sino inicio
            si frente-libre entonces inicio
                avanza;
                recore (n);
            fin
            sino inicio
                si frente-bloqueado y derecha-libre entonces inicio
                    sur;
                    mientras frente-libre hacer
                        avanza;
                    este;
                    avanza;
                    norte;
                    recore (n);
                fin
                sino inicio
                    orienta;
                    mientras junto-a-zumbador hacer
                        coge-zumbador;
                    repetir n veces
                        deja-zumbador;
                fin;
            fin;
        fin;
    fin;
    define-nueva-instruccion bacteria como inicio
        orienta;
        rellena;
        norte;
        recore (0);
    fin;
    inicia-ejecucion
        bacteria;
        apagate;
    termina-ejecucion
finalizar-programa
