iniciar-programa
    define-nueva-instruccion norte como mientras no-orientado-al-norte hacer gira-izquierda;
    define-nueva-instruccion sur como mientras no-orientado-al-sur hacer gira-izquierda;
    define-nueva-instruccion este como mientras no-orientado-al-este hacer gira-izquierda;
    define-nueva-instruccion oeste como mientras no-orientado-al-oeste hacer gira-izquierda;

    define-nueva-instruccion acomodar como inicio
        sur;
        mientras frente-libre hacer avanza;
        oeste;
        mientras frente-libre hacer avanza;
        norte;
    fin;

    define-nueva-instruccion buscar como inicio
        si junto-a-zumbador entonces inicio
        fin sino inicio
            deja-zumbador;
            norte;
            si frente-libre entonces inicio
                avanza;
                si no-junto-a-zumbador entonces buscar;
                sur;
                avanza;
            fin;

            sur;
            si frente-libre entonces inicio
                avanza;
                si no-junto-a-zumbador entonces buscar;
                norte;
                avanza;
            fin;

            este;
            si frente-libre entonces inicio
                avanza;
                si no-junto-a-zumbador entonces buscar;
                oeste;
                avanza;
            fin;

            oeste;
            si frente-libre entonces inicio
                avanza;
                si no-junto-a-zumbador entonces buscar;
                este;
                avanza;
            fin;


        fin;
    fin;

    define-nueva-instruccion espacio como inicio
        si junto-a-zumbador entonces inicio
            si frente-libre entonces inicio
                mientras junto-a-zumbador y frente-libre hacer avanza;
                espacio;
            fin sino inicio
                si derecha-libre entonces inicio
                    este;
                    avanza;
                    sur;
                    mientras frente-libre hacer avanza;
                    norte;
                    espacio;
                fin sino inicio
                acomodar;
                repetir 2 veces coge-zumbador;
                apagate;
                fin;
            fin;
        fin;
    fin;

    define-nueva-instruccion dejar como inicio
        acomodar;
        deja-zumbador;
    fin;



    inicia-ejecucion
        acomodar;
        mientras no (frente-bloqueado y derecha-bloqueada) hacer inicio
            espacio;
            buscar;
            dejar;
        fin;
        apagate;
    termina-ejecucion
finalizar-programa
