iniciar-programa
    define-nueva-instruccion matriuskas como inicio
        si junto-a-zumbador entonces inicio
            coge-zumbador;
            matriuskas;
            si frente-libre entonces avanza;
            deja-zumbador;
        fin;
    fin;
    define-nueva-instruccion cuenta como inicio
        repetir 3 veces gira-izquierda;
        avanza;
        deja-zumbador;
        repetir 2 veces gira-izquierda;
        avanza;
        repetir 3 veces gira-izquierda;
    fin;
    inicia-ejecucion
        mientras junto-a-zumbador y frente-libre hacer avanza;
        repetir 2 veces gira-izquierda;
        si no-junto-a-zumbador entonces avanza;
        mientras junto-a-zumbador hacer inicio
            si frente-bloqueado entonces inicio
                mientras junto-a-zumbador hacer coge-zumbador;
                cuenta;
            fin;
            mientras frente-libre hacer inicio
                si junto-a-zumbador entonces inicio
                    coge-zumbador;
                    si no-junto-a-zumbador entonces inicio
                        deja-zumbador;
                        mientras frente-libre hacer inicio
                            si junto-a-zumbador entonces coge-zumbador;
                            avanza;
                        fin;
                        si junto-a-zumbador entonces coge-zumbador;
                        cuenta;
                    fin;
                fin;
                si frente-libre entonces inicio
                    avanza;
                    si frente-bloqueado y junto-a-zumbador entonces inicio
                        coge-zumbador;
                        si no-junto-a-zumbador entonces inicio
                            cuenta;
                        fin;
                    fin;
                fin;
            fin;
            (*posicion*)
            repetir 2 veces gira-izquierda;
            mientras frente-libre hacer avanza;
            repetir 2 veces gira-izquierda;
            mientras no-junto-a-zumbador y frente-libre hacer avanza;
        fin;
        repetir 3 veces gira-izquierda;
        avanza;
        repetir 2 veces gira-izquierda;
        matriuskas;
        apagate;
    termina-ejecucion
finalizar-programa
