iniciar-programa
    define-nueva-instruccion norte como mientras no orientado-al-norte hacer gira-izquierda;
    define-nueva-instruccion sur como mientras no orientado-al-sur hacer gira-izquierda;
    define-nueva-instruccion este como mientras no orientado-al-este hacer gira-izquierda;
    define-nueva-instruccion oeste como mientras no orientado-al-oeste hacer gira-izquierda;
    define-nueva-instruccion junta(n) como inicio
        si junto-a-zumbador entonces inicio
            coge-zumbador;
            junta(sucede(n));
        fin sino inicio
            norte;
            avanza;
            oeste;
            mientras frente-libre hacer avanza;
            este;
            repetir precede(n) veces avanza;
            deja-zumbador;
        fin;
    fin;
    define-nueva-instruccion regresa como inicio
        oeste;
        mientras frente-libre hacer avanza;
        sur;
        avanza;
        este;
        mientras no-junto-a-zumbador y frente-libre hacer avanza;
    fin;
    define-nueva-instruccion acomoda como inicio
        mientras frente-libre  hacer inicio
            junta(0);
            regresa;
        fin;
        si junto-a-zumbador entonces inicio
            junta(0);
            regresa;
        fin;
        norte;
        avanza;
        oeste;
    fin;
    define-nueva-instruccion recoge(d) como inicio
        mientras frente-libre y no-junto-a-zumbador hacer avanza;
            si junto-a-zumbador entonces inicio
                coge-zumbador;
                si frente-libre entonces inicio
                    avanza;
                fin sino inicio
                    sur;
                    avanza;
                    repetir sucede(d) veces deja-zumbador;
                    apagate;
                fin;
                recoge(sucede(d));
            fin;
            sur;
            avanza;
            repetir d veces deja-zumbador;
            apagate;
    fin;
    inicia-ejecucion
        acomoda;
        recoge(0);
        apagate;
    termina-ejecucion
finalizar-programa
