iniciar-programa
    define-nueva-instruccion gira(n) como repetir n veces gira-izquierda;

    define-nueva-instruccion recogeYacomoda como inicio
        si junto-a-zumbador entonces inicio
            coge-zumbador;
            recogeYacomoda;
            si orientado-al-oeste entonces inicio
                gira(2);
            fin sino inicio
                avanza;
            fin;
        fin sino inicio
            si frente-libre entonces inicio
                avanza;
                recogeYacomoda;
                gira(2);
                si no-junto-a-zumbador entonces deja-zumbador;
                mientras frente-libre hacer avanza;
            fin;
        fin;
    fin;

    define-nueva-instruccion cuentaMatriuskas como inicio
        mientras no-junto-a-zumbador y frente-libre hacer avanza;
        si junto-a-zumbador entonces inicio
            coge-zumbador;
            cuentaMatriuskas;
            deja-zumbador;
        fin;
    fin;

    inicia-ejecucion
        mientras junto-a-zumbador y frente-libre hacer avanza;
        gira(2);
        si no-junto-a-zumbador y frente-libre entonces avanza;
        recogeYacomoda;
        si no-junto-a-zumbador entonces deja-zumbador;
        mientras frente-libre hacer avanza;
        gira(2);
        cuentaMatriuskas;
        apagate;
    termina-ejecucion
finalizar-programa
