iniciar-programa
define-nueva-instruccion gira(n) como repetir n veces gira-izquierda;
define-nueva-instruccion cuenta(k) como inicio
    si junto-a-zumbador entonces inicio
        coge-zumbador;
        cuenta(sucede(k));
    fin sino inicio
        repetir k veces inicio
            si algun-zumbador-en-la-mochila y no-junto-a-zumbador entonces deja-zumbador;
            si frente-libre entonces avanza;
        fin;
    fin;
fin;
define-nueva-instruccion expande como inicio
    gira-izquierda;
    cuenta(0);
    gira(2);
    avanza;
    si frente-libre entonces inicio
        avanza;
        mientras junto-a-zumbador hacer inicio
            coge-zumbador;
            si frente-libre entonces avanza;
        fin;
    fin;
    gira-izquierda;
fin;
define-nueva-instruccion analiza como inicio
    gira-izquierda;
    mientras frente-libre y no-junto-a-zumbador hacer avanza;
    si frente-bloqueado entonces inicio
        gira(2);
        mientras frente-libre hacer avanza;
    fin;
    si junto-a-zumbador entonces inicio
        coge-zumbador;
        gira(2);
        mientras frente-libre hacer avanza;
        si frente-bloqueado entonces deja-zumbador;
    fin;
    gira-izquierda;
fin;
define-nueva-instruccion cuerda(g) como inicio
    mientras no-junto-a-zumbador y frente-libre hacer avanza;
    si junto-a-zumbador entonces inicio
        coge-zumbador;
        si frente-libre entonces avanza;
        cuerda(sucede(g));
    fin sino inicio
        repetir g veces deja-zumbador;
    fin;
fin;
    inicia-ejecucion
mientras no-orientado-al-este hacer gira-izquierda;
mientras (junto-a-zumbador y frente-libre) hacer inicio
    expande;
    avanza;
fin;
gira-izquierda;
mientras frente-libre hacer avanza;
gira-izquierda;
mientras frente-libre hacer avanza;
gira-izquierda;
mientras frente-libre hacer inicio
    analiza;
    avanza;
fin;
si frente-bloqueado entonces analiza;
mientras no-orientado-al-norte hacer gira-izquierda;
mientras frente-libre hacer avanza;
gira(2);
mientras no-junto-a-zumbador y frente-libre hacer avanzA;
si junto-a-zumbador entonces cuerda(0);
        apagate;
    termina-ejecucion
finalizar-programa
 