iniciar-programa
define-nueva-instruccion norte como mientras no-orientado-al-norte hacer gira-izquierda;
define-nueva-instruccion sur como mientras no-orientado-al-sur hacer gira-izquierda;
define-nueva-instruccion este como mientras no-orientado-al-este hacer gira-izquierda;
define-nueva-instruccion oeste como mientras no-orientado-al-oeste hacer gira-izquierda;

define-nueva-instruccion puestos(x) como
inicio
  mientras junto-a-zumbador y orientado-al-este y derecha-bloqueada hacer
    inicio
      coge-zumbador;
      si no-junto-a-zumbador entonces
        inicio
          oeste;
          mientras frente-libre hacer avanza;
          norte;
          avanza;
          este;
          repetir x veces avanza;
          deja-zumbador;
          oeste;
          mientras frente-libre hacer avanza;
          sur;
          avanza;
          este;
        fin;
      puestos(sucede(x));
    fin;
fin;

define-nueva-instruccion matriuskas como
inicio
  mientras orientado-al-este hacer
    inicio
      mientras no-junto-a-zumbador y frente-libre hacer avanza;
      si junto-a-zumbador entonces
        inicio
          mientras junto-a-zumbador hacer coge-zumbador;
          matriuskas;
          si orientado-al-sur entonces deja-zumbador;
        fin;
     si frente-bloqueado y no-junto-a-zumbador y orientado-al-este entonces
      inicio
        oeste;
        mientras frente-libre hacer avanza;
        sur;
        avanza;
      fin;
    fin;
fin;

    inicia-ejecucion
    este;
    mientras orientado-al-este y derecha-bloqueada hacer
      inicio
        mientras no-junto-a-zumbador y frente-libre hacer avanza;
        si frente-bloqueado y no-junto-a-zumbador entonces
          inicio
            oeste;
            mientras frente-libre hacer avanza;
            norte;
          fin;
        si junto-a-zumbador entonces
          inicio
            puestos(0);
          fin;
      fin;
     avanza;
     este;
     matriuskas;
        apagate;
    termina-ejecucion
finalizar-programa
