iniciar-programa
    define-nueva-instruccion gira (n) como inicio
        repetir n veces
            gira-izquierda;
    fin;
    define-nueva-instruccion orienta como inicio
        mientras no-orientado-al-sur hacer
            gira (1);
        mientras frente-libre hacer
            avanza;
        gira (3);
        mientras frente-libre hacer
            avanza;
        gira (2);
    fin;
    define-nueva-instruccion cubetas como inicio
        si junto-a-zumbador entonces inicio
            coge-zumbador;
            gira (1);
            avanza;
            deja-zumbador;
            gira (2);
            avanza;
            gira (1);
            cubetas;
        fin
        sino inicio
            si frente-libre entonces
                avanza;
            si junto-a-zumbador entonces inicio
                cubetas;
            fin;
        fin;
    fin;
    define-nueva-instruccion llena (n) como inicio
        si junto-a-zumbador entonces inicio
            coge-zumbador;
            llena(sucede(n));
        fin
        sino inicio
            orienta;
            repetir precede(n) veces
                avanza;
            deja-zumbador;
        fin;
    fin;
    define-nueva-instruccion cuenta (n) como inicio
        mientras frente-libre y no-junto-a-zumbador hacer
            avanza;
        si junto-a-zumbador entonces inicio
            mientras junto-a-zumbador hacer
                coge-zumbador;
            cuenta(sucede(n));
        fin;
        gira (2);
        mientras frente-libre hacer
            avanza;
        repetir n veces
            deja-zumbador;
        apagate;
    fin;
    inicia-ejecucion
        orienta;
        cubetas;
        orienta;
        gira (1);
        avanza;
        gira (3);
        mientras junto-a-zumbador hacer inicio
            llena(0);
            orienta;
            gira (1);
            avanza;
            gira (3);
            mientras frente-libre y no-junto-a-zumbador hacer
                avanza;
        fin;
        orienta;
        cuenta(0);
        apagate;
    termina-ejecucion
finalizar-programa