iniciar-programa
define-nueva-instruccion norte como mientras no-orientado-al-norte hacer gira-izquierda;
define-nueva-instruccion sur como mientras no-orientado-al-sur hacer gira-izquierda;
define-nueva-instruccion este como mientras no-orientado-al-este hacer gira-izquierda;
define-nueva-instruccion oeste como mientras no-orientado-al-oeste hacer gira-izquierda;

define-nueva-instruccion orilla como
    inicio
        oeste;
    mientras frente-libre hacer avanza;
        este;
    fin;

define-nueva-instruccion comparalo (x)como
    inicio
    si no si-es-cero (x) entonces
        inicio
        si junto-a-zumbador entonces
            inicio
                coge-zumbador;
                comparalo(precede(x));
            si orientado-al-oeste o orientado-al-sur entonces deja-zumbador;
            fin sino
                inicio
                    oeste;
                    avanza;
                fin;
        fin sino
            inicio
                sur;
            fin;
    fin;

define-nueva-instruccion ordena (n) como
    inicio
    si junto-a-zumbador entonces
        inicio
            coge-zumbador;
            ordena(sucede(n));
        fin
    sino
        inicio
        si frente-libre entonces
            inicio
                avanza;
            si junto-a-zumbador entonces
                inicio
                    comparalo(n);
                si orientado-al-sur entonces
                    inicio
                        oeste;
                        avanza;
                        repetir n veces deja-zumbador;
                        este;
                        avanza;
                    fin
                sino
                    inicio
                        este;
                        avanza;
                        repetir n veces deja-zumbador;
                    fin;
                fin
            sino
                inicio
                    oeste;
                    avanza;
                    repetir n veces deja-zumbador;
                    norte;
                fin;
            fin
        sino
            inicio
                repetir n veces deja-zumbador;
                norte;
            fin;
        fin;
    fin;

define-nueva-instruccion cuentalos (max) como
    inicio
    si junto-a-zumbador y frente-libre entonces
        inicio
            avanza;
            cuentalos(sucede(max));
        fin;
        orilla;
    mientras junto-a-zumbador y no-orientado-al-norte hacer ordena(0);
    fin;

define-nueva-instruccion pon(x) como
    inicio
        norte;
        avanza;
        repetir x veces deja-zumbador;
        sur;
        avanza;
        oeste;
    fin;

define-nueva-instruccion dif(x) como
    inicio
    si junto-a-zumbador entonces
        inicio
            coge-zumbador;
            dif(precede(x));
            deja-zumbador;
        fin sino pon(x);
    fin;

define-nueva-instruccion diferencias (x) como
    inicio
    si junto-a-zumbador entonces
        inicio
            coge-zumbador;
            diferencias(sucede(x));
        fin
    sino
        inicio
        si frente-libre entonces
            inicio
                avanza;
            si junto-a-zumbador entonces
                inicio
                   dif(x);
                fin
            sino
                inicio
                    este;
                    avanza;
                    pon(x);
                    norte;
                fin;
            fin sino norte;
        fin;
    fin;

define-nueva-instruccion respuesta como
    inicio
    si junto-a-zumbador entonces
        inicio
            coge-zumbador;
            respuesta;
            deja-zumbador;
        fin
    sino
        inicio
            sur;
        si frente-libre entonces avanza;
        fin;
    fin;

define-nueva-instruccion arranca como
    inicio
        este;
    mientras junto-a-zumbador y frente-libre hacer avanza;
        oeste;
    si no-junto-a-zumbador y frente-libre entonces avanza;
    si junto-a-zumbador entonces cuentalos(0);
        orilla;
    mientras junto-a-zumbador y frente-libre hacer avanza;
        oeste;
    si no-junto-a-zumbador y frente-libre entonces avanza;
    mientras junto-a-zumbador y no-orientado-al-norte hacer diferencias(0);
        si frente-libre entonces avanza;
        este;
    mientras junto-a-zumbador y frente-libre hacer avanza;
        oeste;
    si no-junto-a-zumbador y frente-libre entonces avanza;
    si junto-a-zumbador entonces cuentalos(0);
        orilla;
        respuesta;
    fin;

    inicia-ejecucion
        arranca;
        apagate;
    termina-ejecucion
finalizar-programa
