iniciar-programa
    define-nueva-instruccion norte como mientras no-orientado-al-norte hacer gira-izquierda;
    define-nueva-instruccion sur como mientras no-orientado-al-sur hacer gira-izquierda;
    define-nueva-instruccion este como mientras no-orientado-al-este hacer gira-izquierda;
    define-nueva-instruccion oeste como mientras no-orientado-al-oeste hacer gira-izquierda;

    define-nueva-instruccion skina como
    inicio
        sur;
        mientras frente-libre hacer avanza;
        oeste;
        mientras frente-libre hacer avanza;
        este;
    fin;

    define-nueva-instruccion num2(n) como
    inicio
        si no si-es-cero(n) entonces
        inicio
            si junto-a-zumbador entonces
            inicio
                coge-zumbador;
                num2(precede(n));
                deja-zumbador;
            fin sino
            inicio
                oeste;
                avanza;
            fin;
         fin;
    fin;

    define-nueva-instruccion num1(n) como
    inicio
        si junto-a-zumbador entonces
        inicio
            coge-zumbador;
            num1(sucede(n));
        fin sino
        inicio
            avanza;
            si junto-a-zumbador entonces
            inicio
                num2(n);
                si orientado-al-oeste entonces
                inicio
                    este;
                    avanza;
                    repetir n veces deja-zumbador;
                fin sino
                inicio
                    oeste;
                    avanza;
                    este;
                    repetir n veces deja-zumbador;
                    avanzA;
                fin;
            fin sino
            inicio
                oeste;
                avanza;
                repetir n veces deja-zumbador;
                este;
                avanza;
            fin;
        fin;
    fin;

    define-nueva-instruccion cuenta como
    inicio
        si junto-a-zumbador entonces
        inicio
            avanza;
            cuenta;
            skina;
            si no-junto-a-zumbador entonces
            inicio
                norte;
                avanza;
                este;
            fin;
            mientras junto-a-zumbador hacer num1(0);
        fin;
    fin;

    define-nueva-instruccion compara2(n) como
    inicio
        si no si-es-cero(n) entonces
        inicio
            si junto-a-zumbador entonces
            inicio
                coge-zumbador;
                compara2(precede(n));
                si frente-libre entonces deja-zumbador;
            fin sino
            inicio
                norte;
                avanza;
                repetir n veces deja-zumbador;
                sur;
                avanza;
                oeste;
            fin;
         fin;
    fin;

    define-nueva-instruccion compara1(n) como
    inicio
        si junto-a-zumbador entonces
        inicio
            coge-zumbador;
            compara1(sucede(n));
        fin sino
        inicio
            si frente-libre entonces avanza;
            compara2(n);
        fin;
    fin;

    define-nueva-instruccion distancia como
    inicio
        si junto-a-zumbador entonces
        inicio
            coge-zumbador;
            distancia;
            deja-zumbador;
        fin sino
        inicio
            sur;
            avanza;
        fin;
    fin;

    inicia-ejecucion
        este;
        cuenta;
        oeste;
        avanza;
        mientras frente-libre hacer compara1(0);
        norte;
        avanza;
        este;
        cuenta;
        skina;
        norte;
        avanza;
        distancia;
        apagate;
    termina-ejecucion
finalizar-programa
