iniciar-programa
define-nueva-instruccion norte como mientras no orientado-al-norte hacer gira-izquierda;
define-nueva-instruccion sur como mientras no orientado-al-sur hacer gira-izquierda;
define-nueva-instruccion este como mientras no orientado-al-este hacer gira-izquierda;
define-nueva-instruccion oeste como mientras no orientado-al-oeste hacer gira-izquierda;

define-nueva-instruccion ir11 como
  inicio
    sur;
    mientras frente-libre hacer avanza;
    oeste;
    mientras frente-libre hacer avanza;
    norte;
  fin;

define-nueva-instruccion recoger(n) como
  inicio
    si junto-a-zumbador entonces
      inicio
        coge-zumbador;
        recoger(sucede(n));
      fin
    sino
      inicio
        ir11;
        repetir precede(n) veces avanza;
        deja-zumbador;
      fin;
   fin;

define-nueva-instruccion ordenar como
  inicio
    recoger(0);
    ir11;
    este;
    avanza;
    mientras no junto-a-zumbador y frente-libre hacer avanza;
  fin;

define-nueva-instruccion contar(n) como
  inicio
   si no junto-a-zumbador entonces
     inicio
       si frente-libre entonces avanza sino sal-de-instruccion;
       contar(sucede(n));
     fin
   sino
     inicio
       ir11;
       este;
       repetir n veces avanza;
       si no junto-a-zumbador entonces repetir n veces deja-zumbador;
       ir11;
       mientras no junto-a-zumbador y frente-libre hacer avanza;
     fin;
  fin;

define-nueva-instruccion medir como
  inicio
   coge-zumbador;
   contar(0);
  fin;

define-nueva-instruccion menor(n) como
  inicio
    si junto-a-zumbador entonces
      inicio
        coge-zumbador;
        menor(sucede(n));
      fin
    sino
      inicio
        ir11;
        repetir n veces deja-zumbador;
      fin;
   fin;
    inicia-ejecucion
          este;
          mientras no junto-a-zumbador y frente-libre hacer avanza;
          mientras junto-a-zumbador hacer ordenar;
          ir11;
          mientras no junto-a-zumbador y frente-libre hacer avanza;
          mientras junto-a-zumbador hacer medir;
          ir11;
          este;
          mientras no junto-a-zumbador y frente-libre hacer avanza;
          menor(0);
        apagate;
    termina-ejecucion
finalizar-programa
