iniciar-programa
define-nueva-instruccion norte como
    mientras no orientado-al-norte hacer gira-izquierda;
define-nueva-instruccion sur como
    mientras no orientado-al-sur hacer gira-izquierda;
define-nueva-instruccion este como
    mientras no orientado-al-este hacer gira-izquierda;
define-nueva-instruccion oeste como
    mientras no orientado-al-oeste hacer gira-izquierda;

define-nueva-instruccion tragar(a) como inicio
    si junto-a-zumbador entonces inicio
        coge-zumbador;
        tragar(sucede(a));
        si frente-libre entonces avanza;
        si si-es-cero(a) entonces inicio
            oeste;
            avanza;
            este;
        fin;
    fin;
    si frente-libre y orientado-al-oeste entonces inicio
        avanza;
        tragar(0);
    fin sino inicio
        este;
    fin;
    si si-es-cero(a) entonces inicio
        si no junto-a-zumbador entonces deja-zumbador;
            oeste;
            mientras frente-libre hacer avanza;
            este;
    fin;
fin;
define-nueva-instruccion compara(a) como inicio
    si junto-a-zumbador y no si-es-cero(a) entonces inicio
        coge-zumbador;
        compara(precede(a));
        deja-zumbador;
    fin sino inicio
        si junto-a-zumbador y si-es-cero(a) entonces inicio
            mientras junto-a-zumbador hacer coge-zumbador;
        fin;
    fin;
fin;

define-nueva-instruccion medir(a) como inicio
    si no junto-a-zumbador  entonces inicio
        si frente-libre entonces inicio
            avanza;
        fin sino inicio
            oeste;
            mientras frente-libre hacer avanza;
            sal-de-instruccion;
        fin;
        medir(sucede(a));
    fin sino inicio
        oeste;
        mientras frente-libre hacer avanza;
        si junto-a-zumbador y orientado-al-oeste entonces inicio
            si no si-es-cero (a) entonces compara(a);
            este;
        fin;
    fin;
    si no junto-a-zumbador y orientado-al-oeste entonces inicio
        repetir a veces deja-zumbador;
    fin;
     si si-es-cero(a) entonces inicio
         este;
         avanza;
     fin;
fin;
    inicia-ejecucion
    este;
    mientras junto-a-zumbador hacer avanza;
    oeste;
    avanza;
    tragar(0);
    mientras frente-libre y orientado-al-este hacer inicio
        mientras no junto-a-zumbador y frente-libre hacer avanza;
        si junto-a-zumbador entonces  coge-zumbador;
        si frente-libre entonces  medir(0);
    fin;
    oeste;
    mientras frente-libre hacer avanza;
    este;
        apagate;
    termina-ejecucion
finalizar-programa
 