iniciar-programa

    define-nueva-instruccion norte como inicio
        mientras no orientado-al-norte hacer inicio
            gira-izquierda;
        fin;
    fin;

    define-nueva-instruccion sur como inicio
        mientras no orientado-al-sur hacer inicio
            gira-izquierda;
        fin;
    fin;

    define-nueva-instruccion este como inicio
        mientras no orientado-al-este hacer inicio
            gira-izquierda;
        fin;
    fin;

    define-nueva-instruccion oeste como inicio
        mientras no orientado-al-oeste hacer inicio
            gira-izquierda;
        fin;
    fin;

    define-nueva-instruccion ubicate como inicio
        este;
        mientras frente-libre hacer inicio
            avanza;
        fin;
        oeste;
    fin;

    define-nueva-instruccion reparte(n) como inicio
        si no si-es-cero (n) entonces inicio
            repetir precede(n) veces inicio
                si frente-libre entonces inicio
                    avanza;
                fin;
            fin;
            repetir n veces inicio
                deja-zumbador;
            fin;
            oeste;
            mientras frente-libre hacer inicio
                avanza;
            fin;
            este;
        fin;
    fin;

    define-nueva-instruccion recoge(n) como inicio
        si junto-a-zumbador y derecha-libre entonces inicio
            coge-zumbador;
            recoge(sucede(n));
        fin sino inicio
            si derecha-libre entonces inicio
            si frente-libre entonces inicio
                avanza;
                si junto-a-zumbador entonces inicio
                    recoge(0);
                fin;
                recoge(0);
            fin;
            fin;
            este;
            reparte(n);
        fin;
    fin;

    define-nueva-instruccion ubicate2 como inicio
        oeste;
        mientras frente-libre hacer inicio
            avanza;
        fin;
        este;
        mientras frente-libre y no junto-a-zumbador hacer inicio
            avanza;
        fin;
        mientras junto-a-zumbador hacer inicio
            coge-zumbador;
        fin;
    fin;

    define-nueva-instruccion mide(n) como inicio
        si no junto-a-zumbador y frente-libre entonces inicio
            avanza;
            mide(sucede(n));
        fin sino inicio
            si frente-bloqueado y no junto-a-zumbador entonces inicio
                sal-de-instruccion;
            fin;
            oeste;
            mientras frente-libre hacer inicio
                avanza;
            fin;
            norte;
            avanza;
            este;
            repetir precede(n) veces inicio
                avanza;
            fin;
            si junto-a-zumbador entonces inicio
                norte;
                avanza;
            fin;
            repetir n veces inicio
                deja-zumbador;
            fin;
            oeste;
            mientras frente-libre hacer inicio
                avanza;
            fin;
            sur;
            mientras frente-libre hacer inicio
                avanza;
            fin;
            este;
            ubicate2;
            mide(0);
        fin;
    fin;

    define-nueva-instruccion distancia como inicio
        oeste;
        mientras frente-libre hacer inicio
            avanza;
        fin;
        norte;
        avanza;
        este;
        mientras no junto-a-zumbador y frente-libre hacer inicio
            avanza;
        fin;
    fin;

    define-nueva-instruccion deja(n) como inicio
        si junto-a-zumbador entonces inicio
            coge-zumbador;
            deja(sucede(n));
        fin sino inicio
            oeste;
            mientras frente-libre hacer inicio
                avanza;
            fin;
            sur;
            avanza;
            repetir n veces inicio
                deja-zumbador;
            fin;
        fin;
    fin;

    inicia-ejecucion
        ubicate;
        recoge(0);
        ubicate2;
        mide(0);
        distancia;
        deja(0);
        apagate;
    termina-ejecucion
finalizar-programa
