iniciar-programa
define-nueva-instruccion gira(n) como repetir n veces gira-izquierda;

define-nueva-instruccion ordenar(x) como inicio
    si frente-libre entonces inicio
        avanza;
        si no-junto-a-zumbador entonces ordenar(x);
        si junto-a-zumbador entonces inicio
            coge-zumbador;
            ordenar(sucede(x));
        fin;
    fin sino inicio
        gira(3);
        avanza;
        gira(3);
        repetir x veces inicio
            deja-zumbador;
            avanza;
        fin;
        mientras junto-a-zumbador hacer avanza;
        gira(3);
        avanza;
        gira(3);
    fin;
fin;

define-nueva-instruccion diferencia(z) como inicio
    si junto-a-zumbador entonces inicio
        coge-zumbador;
        diferencia(sucede(z));
    fin sino inicio
        avanza;
        repetir z veces coge-zumbador;
        mientras junto-a-zumbador hacer inicio
            coge-zumbador;
            gira(1);
            avanza;
            deja-zumbador;
            gira(2);
            avanza;
            gira(1);
        fin;
        repetir z veces deja-zumbador;
    fin;
fin;

define-nueva-instruccion suma(m) como inicio
    si junto-a-zumbador entonces inicio
        coge-zumbador;
        suma(sucede(m));
    fin sino inicio
        repetir m veces deja-zumbador;
        gira(2);
        avanza;
        gira(1);
        repetir m veces deja-zumbador;
    fin;
fin;

define-nueva-instruccion final(k) como inicio
    si junto-a-zumbador entonces inicio
        coge-zumbador;
        final(sucede(k));
    fin sino inicio
        mientras frente-libre hacer avanza;
        gira(1);
        avanza;
        repetir k veces deja-zumbador;
        apagate;
    fin;
fin;

    inicia-ejecucion

    gira(3);
    mientras junto-a-zumbador hacer avanza;
    gira(2);

    mientras frente-libre o junto-a-zumbador hacer inicio
        ordenar(0);
        mientras no-junto-a-zumbador y frente-libre hacer avanza;
        si junto-a-zumbador entonces inicio
            gira(2);
            avanza;
            gira(2);
        fin;
    fin;

    gira(3);
    avanza;
    gira(3);
    mientras junto-a-zumbador hacer avanza;
    gira(2);
    avanza;
    mientras frente-libre hacer inicio
        diferencia(0);
        gira(1);
        avanza;
        suma(0);
    fin;
    mientras junto-a-zumbador hacer coge-zumbador;
    gira(1);
    avanza;
    gira(1);
    mientras junto-a-zumbador hacer avanza;
    gira(2);
    mientras frente-libre o junto-a-zumbador hacer inicio
        ordenar(0);
        mientras no-junto-a-zumbador y frente-libre hacer avanza;
        si junto-a-zumbador entonces inicio
            gira(2);
            avanza;
            gira(2);
        fin;
    fin;

    gira(3);
    avanza;
    gira(3);
    mientras junto-a-zumbador hacer avanza;
    gira(2);
    avanza;
    final(0);


        apagate;
    termina-ejecucion
finalizar-programa
