iniciar-programa
    define-nueva-instruccion norte como inicio mientras no orientado-al-norte hacer inicio gira-izquierda; fin; fin;

    define-nueva-instruccion sur como inicio mientras no orientado-al-sur hacer inicio gira-izquierda; fin; fin;

    define-nueva-instruccion este como inicio mientras no orientado-al-este hacer inicio gira-izquierda; fin; fin;

    define-nueva-instruccion oeste como inicio mientras no orientado-al-oeste hacer inicio gira-izquierda; fin; fin;

    define-nueva-instruccion ir11 como inicio
        oeste;
        mientras frente-libre hacer inicio
            avanza;
        fin;
        este;
    fin;

    define-nueva-instruccion ubicar como inicio
        este;
        mientras junto-a-zumbador y frente-libre hacer inicio
            avanza;
        fin;
        oeste;
        si no junto-a-zumbador entonces inicio
            avanza;
        fin;
    fin;

    define-nueva-instruccion ubicar2 como inicio
        ir11;
        norte;
        avanza;
        este;
        mientras frente-libre y no-junto-a-zumbador y orientado-al-este hacer inicio
            avanza;
        fin;
    fin;

    define-nueva-instruccion marcar(n) como inicio
        oeste;
        mientras frente-libre hacer inicio
            avanza;
        fin;
        este;
        repetir n veces inicio
            avanza;
        fin;
        deja-zumbador;
    fin;

    define-nueva-instruccion contar(n) como inicio
        si no-junto-a-zumbador y  frente-libre entonces inicio
            avanza;
            contar(sucede(n));
        fin sino inicio
            norte;
            avanza;
            repetir n veces inicio
                deja-zumbador;
            fin;
            deja-zumbador;
            sur;
            avanza;
            este;
            si frente-libre entonces inicio
                avanza;
            fin;
        fin;
    fin;

    define-nueva-instruccion contar2(n) como inicio
        si no-junto-a-zumbador y  frente-libre entonces inicio
            avanza;
            contar2(sucede(n));
        fin sino inicio
            oeste;
            mientras frente-libre hacer inicio
                avanza;
            fin;
            mientras junto-a-zumbador hacer inicio
                coge-zumbador;
            fin;
            repetir n veces inicio
                deja-zumbador;
            fin;
            deja-zumbador;
        fin;
    fin;

    define-nueva-instruccion recogeymarca(n) como inicio
        si junto-a-zumbador entonces inicio
            coge-zumbador;
            recogeymarca(sucede(n));
        fin sino inicio
            si frente-libre entonces inicio
                avanza;
                recogeymarca(0);
            fin sino inicio
                gira-izquierda;
                gira-izquierda;
            fin;
            marcar(precede(n));
        fin;
    fin;

    define-nueva-instruccion juntar como inicio
        mientras frente-libre y no junto-a-zumbador hacer inicio
            avanza;
        fin;
        mientras junto-a-zumbador hacer inicio
            coge-zumbador;
        fin;
    fin;

    define-nueva-instruccion recorrer(n) como inicio
        si junto-a-zumbador entonces inicio
            oeste;
            coge-zumbador;
            recorrer(sucede(n));
        fin sino inicio
            ir11;
            sur;
            avanza;
            este;
            mientras junto-a-zumbador hacer inicio
                avanza;
            fin;
            repetir n veces inicio
                deja-zumbador;
            fin;
            norte;
            avanza;
            este;
            mientras frente-libre y no-junto-a-zumbador y orientado-al-este hacer inicio
                avanza;                   
            fin;
        fin;
    fin;

    inicia-ejecucion
        ubicar;
        recogeymarca(0);
        ir11;
        este;
        mientras frente-libre y no junto-a-zumbador hacer inicio
            avanza;
        fin;
        si frente-libre entonces inicio
            avanza;
        fin;
        mientras frente-libre hacer inicio
            contar(0);
        fin;
        norte;
        avanza;
        mientras junto-a-zumbador y frente-libre hacer inicio
            coge-zumbador;
        fin;
        sur;
        avanza;
        ir11;
        mientras frente-libre hacer inicio
            juntar;
        fin;
        ubicar2;
        mientras junto-a-zumbador hacer inicio
            recorrer(0);
        fin;
        ir11;
        sur;
        avanza;
        este;
        ubicar;
        recogeymarca(0);
        ir11;
        contar2(0);
        apagate;
    termina-ejecucion
finalizar-programa
