iniciar-programa
define-nueva-instruccion resultado(x) como
inicio
    si junto-a-zumbador entonces
    inicio
        coge-zumbador;
        resultado(sucede(x));
    fin
    sino
    inicio
        repetir 3 veces
            gira-izquierda;
        avanza;
        repetir x veces
            deja-zumbador;
        apagate;
    fin;
fin;
define-nueva-instruccion mueve(x) como
inicio
    si junto-a-zumbador entonces
    inicio
        coge-zumbador;
        mueve(sucede(x));
    fin
    sino
    inicio
        repetir x veces
            deja-zumbador;
         repetir 2 veces
             gira-izquierda;
         mientras frente-libre hacer
             avanza;
         repetir 3 veces
             gira-izquierda;
         avanza;
         repetir 3 veces
             gira-izquierda;
         mientras junto-a-zumbador hacer
             avanza;
         repetir x veces
             deja-zumbador;
         repetir 2 veces
             gira-izquierda;
         mientras frente-libre hacer
             avanza;
         gira-izquierda;
         avanza;
         gira-izquierda;
         mientras no junto-a-zumbador hacer
             avanza;
    fin;
fin;
define-nueva-instruccion ordena(x) como
inicio
    si junto-a-zumbador entonces
    inicio
        coge-zumbador;
        ordena(sucede(x));
    fin
    sino
    inicio
        avanza;
        si junto-a-zumbador entonces
        inicio
            repetir x veces
            inicio
                si junto-a-zumbador entonces
                    coge-zumbador
                sino
                inicio
                    si orientado-al-este entonces
                    inicio
                        repetir 2 veces
                            gira-izquierda;
                        avanza;
                        repetir 3 veces
                            gira-izquierda;
                        repetir x veces
                            deja-zumbador;
                    fin;
                    coge-zumbador;
                fin;
            fin;
            si orientado-al-norte entonces
            inicio
                repetir 3 veces
                    gira-izquierda;
                avanza;
                repetir x veces
                    deja-zumbador;
                ordena(0);
            fin
            sino
            inicio
                repetir x veces
                    deja-zumbador;
                repetir 2 veces
                    gira-izquierda;
                avanza;
                repetir 2 veces
                    gira-izquierda;
                repetir x veces
                    deja-zumbador;
                avanza;
                ordena(0);
            fin;
        fin
        sino
        inicio
            repetir 2 veces
                gira-izquierda;
            avanza;
            repetir x veces
                deja-zumbador;
            mientras frente-libre hacer
                avanza;
            repetir 2 veces
                gira-izquierda;
        fin;
    fin;
fin;
define-nueva-instruccion cuenta(x) como
inicio
    si junto-a-zumbador entonces
    inicio
        avanza;
        cuenta(sucede(x));
    fin
    sino
    inicio
        repetir 2 veces
            gira-izquierda;
        mientras frente-libre hacer
            avanza;
        repetir 2 veces
            gira-izquierda;
        repetir x veces
            ordena(0);
    fin;
fin;
define-nueva-instruccion compara(x) como
inicio
    si junto-a-zumbador entonces
    inicio
        coge-zumbador;
        compara(sucede(x));
    fin
    sino
    inicio
        avanza;
        si junto-a-zumbador entonces
        inicio
            repetir x veces
                coge-zumbador;
            mueve(0);
            repetir x veces
                deja-zumbador;
            compara(0);
        fin;
    fin;
fin;
    inicia-ejecucion
        mientras no orientado-al-este hacer
            gira-izquierda;
        cuenta(0);
        compara(0);
        repetir 2 veces
            gira-izquierda;
        mientras frente-libre hacer
            avanza;
        repetir 3 veces
            gira-izquierda;
        avanza;
        repetir 3 veces
            gira-izquierda;
        cuenta(0);
        resultado(0);

        apagate;
    termina-ejecucion
finalizar-programa
