iniciar-programa
    define-nueva-instruccion gira (n) como inicio
        repetir n veces
            gira-izquierda;
    fin;
    define-nueva-instruccion ordena (n) como inicio
        si junto-a-zumbador entonces inicio
            coge-zumbador;
            ordena (sucede(n));
        fin
        sino inicio
            avanza;
            repetir n veces
                deja-zumbador;
            gira (2);
            avanza;
            gira (1);
            si frente-libre entonces inicio
                avanza;
                si junto-a-zumbador entonces inicio
                    gira (1);
                    ordena (0);
                fin
                sino inicio
                    gira (2);
                    mientras frente-libre hacer
                        avanza;
                    gira (2);
                fin;
            fin
            sino inicio
                gira (2);
                mientras frente-libre hacer
                    avanza;
                gira (2);
            fin;
        fin;
    fin;
    define-nueva-instruccion kuantos (n) como inicio
        si junto-a-zumbador entonces inicio
            coge-zumbador;
            kuantos (sucede(n));
        fin
        sino inicio
            mientras frente-libre hacer
                avanza;
            gira (1);
            avanza;
            gira (1);
            repetir precede (n) veces
                avanza;
            deja-zumbador;
            gira (2);
            mientras frente-libre hacer
                avanza;
            gira (3);
            avanza;
            gira (3);
            mientras frente-libre y junto-a-zumbador hacer
                avanza;
            gira (2);
            si frente-libre entonces inicio
                avanza;
                si junto-a-zumbador entonces inicio
                    kuantos (0);
                fin
                sino inicio
                    gira (1);
                    avanza;
                    gira (1);
                fin;
            fin
            sino inicio
                gira (1);
                avanza;
                gira (1);
            fin;
        fin;
    fin;
    define-nueva-instruccion cuenta (n) como inicio
        si no-junto-a-zumbador entonces inicio
            si frente-libre entonces inicio
                avanza;
                cuenta (sucede(n));
            fin
            sino inicio
                gira (2);
                mientras frente-libre hacer
                    avanza;
                gira (3);
            fin;
        fin
        sino inicio
            gira (2);
            mientras frente-libre hacer
                avanza;
            gira (3);
            repetir precede (n) veces
                avanza;
            deja-zumbador;
        fin;
    fin;
    define-nueva-instruccion cartero (n) como inicio
        si no-junto-a-zumbador entonces inicio
            avanza;
            cartero (sucede(n));
        fin
        sino inicio
            gira (2);
            mientras frente-libre hacer
                avanza;
            gira (1);
            mientras junto-a-zumbador hacer
                coge-zumbador;
            repetir sucede (n) veces
                deja-zumbador;
        fin;
    fin;
    define-nueva-instruccion casas como inicio
        si junto-a-zumbador entonces inicio
            coge-zumbador;
            cuenta (0);
            gira (2);
            mientras frente-libre hacer
                avanza;
            gira (1);
            avanza;
            mientras frente-libre y no-junto-a-zumbador hacer
                avanza;
            si junto-a-zumbador entonces inicio
                casas;
            fin
            sino inicio
                gira (2);
                mientras frente-libre hacer
                    avanza;
                gira (3);
                cartero (0);
            fin;
        fin;
    fin;
    inicia-ejecucion
        ordena (0);
        gira (1);
        avanza;
        gira (3);
        mientras frente-libre y junto-a-zumbador hacer
            avanza;
        gira (2);
        avanza;
        kuantos (0);
        mientras frente-libre y no-junto-a-zumbador hacer
            avanza;
        casas;
        apagate;
    termina-ejecucion
finalizar-programa