iniciar-programa
define-prototipo-instruccion escala(n);
define-nueva-instruccion norte como mientras no-orientado-al-norte hacer gira-izquierda;
define-nueva-instruccion sur como mientras no-orientado-al-sur hacer gira-izquierda;
define-nueva-instruccion oeste como mientras no-orientado-al-oeste hacer gira-izquierda;
define-nueva-instruccion este como mientras no-orientado-al-este hacer gira-izquierda;
define-nueva-instruccion faltante(n) como
    inicio
       si junto-a-zumbador entonces
           inicio
              coge-zumbador;
              faltante(sucede(n));
           fin sino
               inicio
                   sur;
                   mientras frente-libre hacer avanza;
                   este;
                   si frente-libre entonces
                       inicio
                           avanza;
                           norte;
                           mientras junto-a-zumbador hacer avanza;
                           sur;
                           avanza;
                           faltante(n);
                       fin sino
                           inicio
                              oeste;
                              mientras frente-libre hacer avanza;
                              este;
                              mientras no-junto-a-zumbador hacer avanza;
                              coge-zumbador;
                              repetir n veces deja-zumbador;
                              apagate;
                           fin;
               fin;
    fin;
define-nueva-instruccion resta(n) como
    inicio
        si no si-es-cero(n) entonces
            inicio
                si junto-a-zumbador entonces
                    inicio
                        coge-zumbador;
                        resta(precede(n));
                    fin sino
                        inicio
                            mientras frente-libre hacer avanza;
                            este;
                            si frente-libre entonces
                                inicio
                                    avanza;
                                    escala(n);
                                fin sino
                                    inicio
                                        norte;
                                        mientras derecha-bloqueada hacer avanza;
                                        repetir 3 veces gira-izquierda;
                                        avanza;
                                        repetir n veces deja-zumbador;
                                        apagate;
                                    fin;
                        fin;
            fin sino
                inicio
                   mientras frente-libre hacer faltante(0);
                fin;
    fin;
define-nueva-instruccion escala(n) como
    inicio
        si junto-a-zumbador entonces
            inicio
                norte;
                mientras junto-a-zumbador hacer avanza;
                sur;
                avanza;
                resta(n);
            fin;
    fin;
define-nueva-instruccion vitaminas(n) como
    inicio
        si junto-a-zumbador entonces
            inicio
                coge-zumbador;
                vitaminas(sucede(n));
            fin sino
                inicio
                    deja-zumbador;
                    este;
                    avanza;
                    norte;
                    mientras frente-libre hacer escala(n);
                fin;
    fin;
    inicia-ejecucion
        mientras algun-zumbador-en-la-mochila hacer deja-zumbador;
        vitaminas(0);
        apagate;
    termina-ejecucion
finalizar-programa
